pkgs/tools/system/awstats/default.nix

   1 { lib
   2 , fetchurl
   3 , perlPackages
   4 , jdk
   5 }:
   6
   7 perlPackages.buildPerlPackage rec {
   8   pname = "awstats";
   9   version = "7.9";
  10
  11   src = fetchurl {
  12     url = "mirror://sourceforge/awstats/${pname}-${version}.tar.gz";
  13     sha256 = "sha256-YVF47TE9NDFfFaUi2xpdEsqcOV43hbsGKAq/+V2aBUY=";
  14   };
  15
  16   postPatch = ''
  17     substituteInPlace wwwroot/cgi-bin/awstats.pl \
  18       --replace /usr/share/awstats/ "$out/wwwroot/cgi-bin/"
  19   '';
  20
  21   outputs = [ "bin" "out" "doc" ]; # bin just links the user-run executable
  22
  23   propagatedBuildOutputs = [ ]; # otherwise out propagates bin -> cycle
  24
  25   buildInputs = with perlPackages; [ ]; # plugins will need some
  26
  27   preConfigure = ''
  28     touch Makefile.PL
  29     patchShebangs .
  30   '';
  31
  32   # build our own JAR
  33   preBuild = ''
  34     (
  35       cd wwwroot/classes/src
  36       rm ../*.jar
  37       PATH="${jdk}/bin" "$(type -P perl)" Makefile.pl
  38       test -f ../*.jar
  39     )
  40   '';
  41
  42   doCheck = false;
  43
  44   installPhase = ''
  45     mkdir "$out"
  46     mv wwwroot "$out/wwwroot"
  47     rm -r "$out/wwwroot/classes/src/"
  48
  49     mkdir -p "$out/share/awstats"
  50     mv tools "$out/share/awstats/tools"
  51
  52     mkdir -p "$bin/bin"
  53     ln -s "$out/wwwroot/cgi-bin/awstats.pl" "$bin/bin/awstats"
  54
  55     mkdir -p "$doc/share/doc"
  56     mv README.md docs/
  57     mv docs "$doc/share/doc/awstats"
  58   '';
  59
  60   meta = with lib; {
  61     changelog = "https://www.awstats.org/docs/awstats_changelog.txt";
  62     description = "Real-time logfile analyzer to get advanced statistics";
  63     homepage = "https://awstats.org";
  64     license = licenses.gpl3Plus;
  65     platforms = platforms.unix;
  66     mainProgram = "awstats";
  67   };
  68 }