pkgs/os-specific/linux/rtl8821ce/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   kernel,
   6   bc,
   7 }:
   8
   9 stdenv.mkDerivation (finalAttrs: {
  10   pname = "rtl8821ce";
  11   version = "${kernel.version}-unstable-2024-03-26";
  12
  13   src = fetchFromGitHub {
  14     owner = "tomaspinho";
  15     repo = "rtl8821ce";
  16     rev = "f119398d868b1a3395f40c1df2e08b57b2c882cd";
  17     hash = "sha256-EfpKa5ZRBVM5T8EVim3cVX1PP1UM9CyG6tN5Br8zYww=";
  18   };
  19
  20   hardeningDisable = [ "pic" ];
  21
  22   nativeBuildInputs = [ bc ] ++ kernel.moduleBuildDependencies;
  23   makeFlags = kernel.makeFlags;
  24
  25   prePatch = ''
  26     substituteInPlace ./Makefile \
  27       --replace /lib/modules/ "${kernel.dev}/lib/modules/" \
  28       --replace /sbin/depmod \# \
  29       --replace '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  30   '';
  31
  32   preInstall = ''
  33     mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  34   '';
  35
  36   enableParallelBuilding = true;
  37
  38   meta = {
  39     description = "Realtek rtl8821ce driver";
  40     homepage = "https://github.com/tomaspinho/rtl8821ce";
  41     license = lib.licenses.gpl2Only;
  42     platforms = lib.platforms.linux;
  43     maintainers = with lib.maintainers; [
  44       hhm
  45       defelo
  46     ];
  47     broken =
  48       stdenv.hostPlatform.isAarch64
  49       || ((lib.versions.majorMinor kernel.version) == "5.4" && kernel.isHardened);
  50   };
  51 })