pkgs/tools/X11/nx-libs/default.nix

   1 { lib, stdenv, autoconf, automake, fetchFromGitHub, fetchpatch
   2 , libjpeg_turbo
   3 , libpng, libtool, libxml2, pkg-config, which, xorg
   4 , libtirpc
   5 }:
   6 stdenv.mkDerivation rec {
   7   pname = "nx-libs";
   8   version = "3.5.99.26";
   9   src = fetchFromGitHub {
  10     owner = "ArcticaProject";
  11     repo = "nx-libs";
  12     rev = version;
  13     sha256 = "sha256-qVOdD85sBMxKYx1cSLAGKeODsKKAm9UPBmYzPBbBOzQ=";
  14   };
  15
  16   patches = [
  17     (fetchpatch {
  18       name = "binutils-2.36.patch";
  19       url = "https://github.com/ArcticaProject/nx-libs/commit/605a266911b50ababbb3f8a8b224efb42743379c.patch";
  20       sha256 = "sha256-kk5ms3i0PrHL74I4OlsqDrdDcCJ0us03cQcBy4zjAoQ=";
  21     })
  22   ];
  23
  24   nativeBuildInputs = [ autoconf automake libtool pkg-config which
  25     xorg.gccmakedep xorg.imake ];
  26   buildInputs = [ libjpeg_turbo libpng libxml2 xorg.fontutil
  27     xorg.libXcomposite xorg.libXdamage xorg.libXdmcp xorg.libXext xorg.libXfont2
  28     xorg.libXinerama xorg.libXpm xorg.libXrandr xorg.libXtst xorg.pixman
  29     xorg.xkbcomp xorg.xkeyboardconfig libtirpc
  30   ];
  31
  32   env.NIX_CFLAGS_COMPILE = toString [ "-I${libtirpc.dev}/include/tirpc" ];
  33   NIX_LDFLAGS = [ "-ltirpc" ];
  34
  35   postPatch = ''
  36     patchShebangs .
  37     find . -type f -name Makefile -exec sed -i 's|^\(SHELL:=\)/bin/bash$|\1${stdenv.shell}|g' {} \;
  38     ln -s libNX_X11.so.6.3.0
  39   '';
  40
  41   preConfigure = ''
  42     # binutils 2.37 fix
  43     # https://github.com/ArcticaProject/nx-libs/issues/1003
  44     substituteInPlace nx-X11/config/cf/Imake.tmpl --replace "clq" "cq"
  45   '';
  46
  47   PREFIX=""; # Don't install to $out/usr/local
  48   installPhase = ''
  49     make DESTDIR="$out" install
  50     # See:
  51     # - https://salsa.debian.org/debian-remote-team/nx-libs/blob/bcc152100617dc59156015a36603a15db530a64f/debian/rules#L66-72
  52     # - https://github.com/ArcticaProject/nx-libs/issues/652
  53     patchelf --remove-needed "libX11.so.6" $out/bin/nxagent
  54   '';
  55
  56   meta = {
  57     description = "NX X server based on Xnest";
  58     homepage = "https://github.com/ArcticaProject/nx-libs";
  59     license = lib.licenses.gpl2Only;
  60     maintainers = [ ];
  61     platforms = lib.platforms.linux;
  62   };
  63 }