pkgs/tools/networking/networkmanager/fortisslvpn/default.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , substituteAll
   5 , openfortivpn
   6 , gettext
   7 , pkg-config
   8 , file
   9 , glib
  10 , gtk3
  11 , gtk4
  12 , networkmanager
  13 , ppp
  14 , libsecret
  15 , withGnome ? true
  16 , gnome
  17 , libnma
  18 , libnma-gtk4
  19 }:
  20
  21 stdenv.mkDerivation rec {
  22   pname = "NetworkManager-fortisslvpn";
  23   version = "1.4.0";
  24   name = "${pname}${lib.optionalString withGnome "-gnome"}-${version}";
  25
  26   src = fetchurl {
  27     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  28     sha256 = "sFXiY0m1FrI1hXmKs+9XtDawFIAOkqiscyz8jnbF2vo=";
  29   };
  30
  31   patches = [
  32     (substituteAll {
  33       src = ./fix-paths.patch;
  34       inherit openfortivpn;
  35     })
  36   ];
  37
  38   nativeBuildInputs = [
  39     gettext
  40     pkg-config
  41     file
  42   ];
  43
  44   buildInputs = [
  45     openfortivpn
  46     networkmanager
  47     ppp
  48     glib
  49   ] ++ lib.optionals withGnome [
  50     gtk3
  51     gtk4
  52     libsecret
  53     libnma
  54     libnma-gtk4
  55   ];
  56
  57   configureFlags = [
  58     "--with-gnome=${if withGnome then "yes" else "no"}"
  59     "--with-gtk4=${if withGnome then "yes" else "no"}"
  60     "--localstatedir=/var"
  61     "--enable-absolute-paths"
  62   ];
  63
  64   installFlags = [
  65     # the installer only creates an empty directory in localstatedir, so
  66     # we can drop it
  67     "localstatedir=."
  68   ];
  69
  70   passthru = {
  71     updateScript = gnome.updateScript {
  72       packageName = pname;
  73       attrPath = "networkmanager-fortisslvpn";
  74       versionPolicy = "odd-unstable";
  75     };
  76     networkManagerPlugin = "VPN/nm-fortisslvpn-service.name";
  77   };
  78
  79   meta = with lib; {
  80     description = "NetworkManager’s FortiSSL plugin";
  81     inherit (networkmanager.meta) maintainers platforms;
  82     license = licenses.gpl2;
  83   };
  84 }