pkgs/tools/package-management/appimage-run/test.nix

   1 { runCommand, fetchurl, appimage-run, glibcLocales, file, xdg-utils }:
   2 let
   3   # any AppImage usable on cli, really
   4   sample-appImage = fetchurl {
   5     url = "https://github.com/AppImage/AppImageKit/releases/download/12/appimagetool-x86_64.AppImage";
   6     sha256 =  "04ws94q71bwskmhizhwmaf41ma4wabvfgjgkagr8wf3vakgv866r";
   7   };
   8   owdtest = fetchurl {
   9     url = "https://github.com/NixOS/nixpkgs/files/10099048/owdtest.AppImage.gz";
  10     sha256 = "sha256-EEp9dxz/+l5XkNaVBFgv5v64sizQILnljRAzwXv/yV8=";
  11   };
  12 in
  13   runCommand "appimage-run-tests" {
  14     buildInputs = [ appimage-run glibcLocales file xdg-utils ];
  15     meta.platforms = [ "x86_64-linux" ];
  16   }
  17   ''
  18     export HOME=$(mktemp -d)
  19     set -x
  20
  21     # regression test for #101137, must come first
  22     LANG=fr_FR appimage-run ${sample-appImage} --list ${sample-appImage}
  23
  24     # regression test for #108426
  25     cp ${sample-appImage} foo.appImage
  26     LANG=fr_FR appimage-run ${sample-appImage} --list foo.appImage
  27     cp ${owdtest} owdtest.AppImage.gz
  28     gunzip owdtest.AppImage.gz
  29     appimage-run owdtest.AppImage
  30
  31     # Verify desktop entry
  32     XDG_DATA_DIRS="${appimage-run}/share"
  33     [[ "$(xdg-mime query default application/vnd.appimage)" == '${appimage-run.name}.desktop' ]]
  34
  35     set +x
  36     touch $out
  37   ''