pkgs/applications/misc/inlyne/default.nix

   1 { lib
   2 , rustPlatform
   3 , fetchFromGitHub
   4 , installShellFiles
   5 , stdenv
   6 , pkg-config
   7 , fontconfig
   8 , xorg
   9 , libGL
  10 , openssl
  11 , darwin
  12 }:
  13
  14 rustPlatform.buildRustPackage rec {
  15   pname = "inlyne";
  16   version = "0.3.1";
  17
  18   src = fetchFromGitHub {
  19     owner = "trimental";
  20     repo = pname;
  21     rev = "v${version}";
  22     hash = "sha256-B+H3G4jVysqrzWIP+1hktSGnycZLizxhmBCO/lYIr0I=";
  23   };
  24
  25   cargoHash = "sha256-LFL2DVKu/UM7effikZN/IhSD6DrlwO+CF+S60PXULa0=";
  26
  27   nativeBuildInputs = [
  28     installShellFiles
  29   ] ++ lib.optionals stdenv.isLinux [
  30     pkg-config
  31   ];
  32
  33   buildInputs = lib.optionals stdenv.isLinux [
  34     fontconfig
  35     xorg.libXcursor
  36     xorg.libXi
  37     xorg.libXrandr
  38     xorg.libxcb
  39     openssl
  40   ] ++ lib.optionals stdenv.isDarwin [
  41     darwin.apple_sdk_11_0.frameworks.AppKit
  42   ];
  43
  44   postInstall = ''
  45     installShellCompletion --cmd inlyne \
  46       --bash <($out/bin/inlyne --gen-completions bash) \
  47       --fish <($out/bin/inlyne --gen-completions fish) \
  48       --zsh <($out/bin/inlyne --gen-completions zsh)
  49   '';
  50
  51   postFixup = lib.optionalString stdenv.isLinux ''
  52     patchelf $out/bin/inlyne \
  53       --add-rpath ${lib.makeLibraryPath [ libGL xorg.libX11 ]}
  54   '';
  55
  56   meta = with lib; {
  57     description = "A GPU powered browserless markdown viewer";
  58     homepage = "https://github.com/trimental/inlyne";
  59     changelog = "https://github.com/trimental/inlyne/releases/tag/${src.rev}";
  60     license = licenses.mit;
  61     maintainers = with maintainers; [ figsoda ];
  62   };
  63 }