pkgs/applications/radio/svxlink/default.nix

   1 { lib, stdenv, cmake, pkg-config, fetchFromGitHub, makeDesktopItem, alsa-lib, speex
   2 , libopus, curl, gsm, libgcrypt, libsigcxx, popt, qtbase, qttools
   3 , wrapQtAppsHook, rtl-sdr, tcl, doxygen, groff }:
   4
   5 let
   6   desktopItem = makeDesktopItem rec {
   7     name = "Qtel";
   8     exec = "qtel";
   9     icon = "qtel";
  10     desktopName = name;
  11     genericName = "EchoLink Client";
  12     categories = [ "HamRadio" "Qt" "Network" ];
  13   };
  14
  15 in stdenv.mkDerivation rec {
  16   pname = "svxlink";
  17   version = "19.09.2";
  18
  19   src = fetchFromGitHub {
  20     owner = "sm0svx";
  21     repo = pname;
  22     rev = version;
  23     sha256 = "sha256-riyFEuEmJ7+jYT3UoTTsMUwFdO3y5mjo4z0fcC3O8gY=";
  24   };
  25
  26   cmakeFlags = [
  27     "-DDO_INSTALL_CHOWN=NO"
  28     "-DRTLSDR_LIBRARIES=${rtl-sdr}/lib/librtlsdr.so"
  29     "-DRTLSDR_INCLUDE_DIRS=${rtl-sdr}/include"
  30     "../src"
  31   ];
  32   dontWrapQtApps = true;
  33
  34   nativeBuildInputs = [ cmake pkg-config doxygen groff wrapQtAppsHook ];
  35
  36   buildInputs = [
  37     alsa-lib
  38     curl
  39     gsm
  40     libgcrypt
  41     libsigcxx
  42     libopus
  43     popt
  44     qtbase
  45     qttools
  46     rtl-sdr
  47     speex
  48     tcl
  49   ];
  50
  51   postInstall = ''
  52     rm -f $out/share/applications/*
  53     cp -v ${desktopItem}/share/applications/* $out/share/applications
  54     mv $out/share/icons/link.xpm $out/share/icons/qtel.xpm
  55
  56     wrapQtApp $out/bin/qtel
  57   '';
  58
  59   meta = with lib; {
  60     description = "Advanced repeater controller and EchoLink software";
  61     longDescription = ''
  62       Advanced repeater controller and EchoLink software for Linux including a
  63       GUI, Qtel - The Qt EchoLink client
  64     '';
  65     homepage = "http://www.svxlink.org/";
  66     license = with licenses; [ gpl2 ];
  67     maintainers = with maintainers; [ zaninime ];
  68     platforms = platforms.linux;
  69   };
  70 }