pkgs/development/julia-modules/util.nix

   1 { git
   2 , runCommand
   3 }:
   4
   5 {
   6   # Add packages to a Python environment. Works if you pass something like either
   7   # a) python3
   8   # b) python3.withPackages (ps: [...])
   9   # See https://github.com/NixOS/nixpkgs/pull/97467#issuecomment-689315186
  10   addPackagesToPython = python: packages:
  11     if python ? "env" then python.override (old: {
  12       extraLibs = old.extraLibs ++ packages;
  13     })
  14     else python.withPackages (ps: packages);
  15
  16   # Convert an ordinary source checkout into a repo with a single commit
  17   repoifySimple = name: path:
  18     runCommand ''${name}-repoified'' {buildInputs = [git];} ''
  19       mkdir -p $out
  20       cp -r ${path}/. $out
  21       cd $out
  22       chmod -R u+w .
  23       rm -rf .git
  24       git init
  25       git add . -f
  26       git config user.email "julia2nix@localhost"
  27       git config user.name "julia2nix"
  28       git commit -m "Dummy commit"
  29     '';
  30
  31   # Convert an dependency source info into a repo with a single commit
  32   repoifyInfo = uuid: info:
  33     runCommand ''julia-${info.name}-${info.version}'' {buildInputs = [git];} ''
  34       mkdir -p $out
  35       cp -r ${info.src}/. $out
  36       cd $out
  37       chmod -R u+w .
  38       rm -rf .git
  39       git init
  40       git add . -f
  41       git config user.email "julia2nix@localhost"
  42       git config user.name "julia2nix"
  43       git commit -m "Dummy commit"
  44     '';
  45 }