pkgs/misc/screensavers/betterlockscreen/default.nix

   1 { fetchFromGitHub
   2 , lib
   3 , makeWrapper
   4 , stdenv
   5
   6   # Dependencies (@see https://github.com/pavanjadhaw/betterlockscreen/blob/master/shell.nix)
   7 , bc
   8 , coreutils
   9 , dbus
  10 , withDunst ? true
  11 , dunst
  12 , i3lock-color
  13 , gawk
  14 , gnugrep
  15 , gnused
  16 , imagemagick
  17 , procps
  18 , xorg
  19 }:
  20
  21 let
  22   runtimeDeps =
  23     [ bc coreutils dbus i3lock-color gawk gnugrep gnused imagemagick procps xorg.xdpyinfo xorg.xrandr xorg.xset ]
  24     ++ lib.optionals withDunst [ dunst ];
  25 in
  26
  27 stdenv.mkDerivation rec {
  28   pname = "betterlockscreen";
  29   version = "4.4.0";
  30
  31   src = fetchFromGitHub {
  32     owner = "betterlockscreen";
  33     repo = "betterlockscreen";
  34     rev = "v${version}";
  35     sha256 = "sha256-59Ct7XIfZqU3yaW9FO7UV8SSMLdcZMPRc7WJangxFPo=";
  36   };
  37
  38   nativeBuildInputs = [ makeWrapper ];
  39
  40   installPhase = ''
  41     runHook preInstall
  42
  43     mkdir -p $out/bin
  44     cp betterlockscreen $out/bin/betterlockscreen
  45     wrapProgram "$out/bin/betterlockscreen" \
  46       --prefix PATH : "$out/bin:${lib.makeBinPath runtimeDeps}"
  47
  48     runHook postInstall
  49   '';
  50
  51   meta = with lib; {
  52     description = "Fast and sweet looking lockscreen for linux systems with effects!";
  53     homepage = "https://github.com/betterlockscreen/betterlockscreen";
  54     mainProgram = "betterlockscreen";
  55     license = licenses.mit;
  56     platforms = platforms.linux;
  57     maintainers = with maintainers; [ eyjhb sebtm ];
  58   };
  59 }