pkgs/development/gnuradio-modules/rds/default.nix

   1 { lib
   2 , mkDerivation
   3 , fetchFromGitHub
   4 , gnuradio
   5 , cmake
   6 , pkg-config
   7 , swig
   8 , python
   9 , logLib
  10 , mpir
  11 , thrift
  12 , boost
  13 , gmp
  14 , icu
  15 , gnuradioAtLeast
  16 }:
  17
  18 let
  19   version = {
  20     "3.7" = "1.1.0";
  21     "3.8" = "3.8.0";
  22     "3.9" = null;
  23   }.${gnuradio.versionAttr.major};
  24   src = fetchFromGitHub {
  25     owner = "bastibl";
  26     repo = "gr-rds";
  27     rev = "v${version}";
  28     sha256 = {
  29       "3.7" = "0jkzchvw0ivcxsjhi1h0mf7k13araxf5m4wi5v9xdgqxvipjzqfy";
  30       "3.8" = "+yKLJu2bo7I2jkAiOdjvdhZwxFz9NFgTmzcLthH9Y5o=";
  31       "3.9" = null;
  32     }.${gnuradio.versionAttr.major};
  33   };
  34 in mkDerivation {
  35   pname = "gr-rds";
  36   inherit version src;
  37   disabled = gnuradioAtLeast "3.9";
  38
  39   buildInputs = [
  40     logLib
  41     mpir
  42     boost
  43     gmp
  44     icu
  45   ] ++ lib.optionals (gnuradio.hasFeature "gr-ctrlport") [
  46     thrift
  47     python.pkgs.thrift
  48   ];
  49
  50   nativeBuildInputs = [
  51     cmake
  52     pkg-config
  53     swig
  54     python
  55   ];
  56
  57   meta = with lib; {
  58     description = "Gnuradio block for radio data system";
  59     homepage = "https://github.com/bastibl/gr-rds";
  60     license = licenses.gpl2Plus;
  61     platforms = platforms.unix;
  62     maintainers = with maintainers; [ mog ];
  63   };
  64 }