pkgs/development/ocaml-modules/reason-native/default.nix

   1 { newScope, lib, fetchFromGitHub, callPackage, buildDunePackage, atdgen, junit, qcheck-core, re, reason, reason-native, fetchpatch }:
   2
   3 let
   4   generic = (somePath:
   5     let
   6       prepkg = import somePath {
   7         inherit callPackage cli buildDunePackage atdgen junit qcheck-core re reason fetchpatch;
   8         inherit (reason-native) console file-context-printer fp pastel rely;
   9       };
  10     in
  11       buildDunePackage
  12         ({
  13           version = "2022-08-31-a0ddab6";
  14           src = fetchFromGitHub {
  15             owner = "reasonml";
  16             repo = "reason-native";
  17             rev = "a0ddab6ab25237961e32d8732b0a222ec2372d4a";
  18             hash = "sha256-s2N5OFTwIbKXcv05gQRaBMCHO1Mj563yhryPeo8jMh8=";
  19           };
  20           duneVersion = "3";
  21           meta = with lib; {
  22             description = "Libraries for building and testing native Reason programs";
  23             downloadPage = "https://github.com/reasonml/reason-native";
  24             homepage = "https://reason-native.com/";
  25             license = licenses.mit;
  26             maintainers = with maintainers; [ ];
  27           } // (prepkg.meta or {});
  28         } // prepkg)
  29   );
  30   cli = generic ./cli.nix; # Used only by Rely.
  31 in
  32   lib.makeScope newScope (self: with self; {
  33     console = generic ./console.nix;
  34     dir = generic ./dir.nix;
  35     file-context-printer = generic ./file-context-printer.nix;
  36     fp = generic ./fp.nix;
  37     pastel = generic ./pastel.nix;
  38     pastel-console = generic ./pastel-console.nix;
  39     qcheck-rely = generic ./qcheck-rely.nix;
  40     refmterr = generic ./refmterr.nix;
  41     rely = generic ./rely.nix;
  42     rely-junit-reporter = generic ./rely-junit-reporter.nix;
  43   })