external/libpng-1.6.37/configure.ac

   1 # configure.ac
   2
   3 # Copyright (c) 2018 Cosmin Truta
   4 # Copyright (c) 2004-2016 Glenn Randers-Pehrson
   5
   6 # This code is released under the libpng license.
   7 # For conditions of distribution and use, see the disclaimer
   8 # and license in png.h
   9
  10 dnl Process this file with autoconf to produce a configure script.
  11 dnl
  12 dnl Minor upgrades (compatible ABI): increment the package version
  13 dnl (third field in two places below) and set the PNGLIB_RELEASE
  14 dnl variable.
  15 dnl
  16 dnl Major upgrades (incompatible ABI): increment the package major
  17 dnl version (second field, or first if desired), set the minor
  18 dnl to 0, set PNGLIB_MAJOR below *and* follow the instructions in
  19 dnl Makefile.am to upgrade the package name.
  20
  21 dnl This is here to prevent earlier autoconf from being used, it
  22 dnl should not be necessary to regenerate configure if the time
  23 dnl stamps are correct
  24 AC_PREREQ([2.68])
  25
  26 dnl Version number stuff here:
  27
  28 AC_INIT([libpng],[1.6.37],[png-mng-implement@lists.sourceforge.net])
  29 AC_CONFIG_MACRO_DIR([scripts])
  30
  31 # libpng does not follow GNU file name conventions (hence 'foreign')
  32 # color-tests requires automake 1.11 or later
  33 # silent-rules requires automake 1.11 or later
  34 # dist-xz requires automake 1.11 or later
  35 # 1.12.2 fixes a security issue in 1.11.2 and 1.12.1
  36 # 1.13 is required for parallel tests
  37 AM_INIT_AUTOMAKE([1.13 foreign dist-xz color-tests silent-rules subdir-objects])
  38 # The following line causes --disable-maintainer-mode to be the default to
  39 # configure. This is necessary because libpng distributions cannot rely on the
  40 # time stamps of the autotools generated files being correct
  41 AM_MAINTAINER_MODE
  42
  43 dnl configure.ac and Makefile.am expect automake 1.11.2 or a compatible later
  44 dnl version; aclocal.m4 will generate a failure if you use a prior version of
  45 dnl automake, so the following is not necessary (and is not defined anyway):
  46 dnl AM_PREREQ([1.11.2])
  47 dnl stop configure from automagically running automake
  48
  49 PNGLIB_VERSION=1.6.37
  50 PNGLIB_MAJOR=1
  51 PNGLIB_MINOR=6
  52 PNGLIB_RELEASE=37
  53
  54 dnl End of version number stuff
  55
  56 AC_CONFIG_SRCDIR([pngget.c])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 # Checks for programs.
  60 AC_LANG([C])
  61 AC_PROG_CC
  62 AM_PROG_AS
  63 LT_PATH_LD
  64 AC_PROG_CPP
  65 AC_PROG_AWK
  66 AC_PROG_INSTALL
  67 AC_PROG_LN_S
  68 AC_PROG_MAKE_SET
  69
  70 dnl libtool/libtoolize; version 2.4.2 is the tested version. This or any
  71 dnl compatible later version may be used
  72 LT_INIT([win32-dll])
  73 LT_PREREQ([2.4.2])
  74
  75 # Some awks crash when confronted with pnglibconf.dfa, do a test run now
  76 # to make sure this doesn't happen
  77 AC_MSG_CHECKING([that AWK works])
  78 if ${AWK} -f ${srcdir}/scripts/options.awk out="/dev/null" version=search\
  79    ${srcdir}/pngconf.h ${srcdir}/scripts/pnglibconf.dfa\
  80    ${srcdir}/pngusr.dfa 1>&2
  81 then
  82    AC_MSG_RESULT([ok])
  83 else
  84    AC_MSG_FAILURE([failed], 1)
  85 fi
  86
  87 # This is a remnant of the old cc -E validation, where it may have been
  88 # necessary to use a different preprocessor for .dfn files
  89 DFNCPP="$CPP"
  90 AC_SUBST(DFNCPP)
  91
  92 # -Werror cannot be passed to GCC in CFLAGS because configure will fail (it
  93 # checks the compiler with a program that generates a warning), add the
  94 # following option to deal with this
  95 AC_ARG_VAR(PNG_COPTS,
  96    [additional flags for the C compiler, use this for options that would]
  97    [cause configure itself to fail])
  98 AC_ARG_ENABLE(werror,
  99    AS_HELP_STRING([[[--enable-werror[=OPT]]]],
 100       [Pass -Werror or the given argument to the compiler if it is supported]),
 101    [test "$enable_werror" = "yes" && enable_werror="-Werror"
 102     if test "$enable_werror" != "no"; then
 103       sav_CFLAGS="$CFLAGS"
 104       CFLAGS="$enable_werror $CFLAGS"
 105       AC_MSG_CHECKING([if the compiler allows $enable_werror])
 106       AC_COMPILE_IFELSE(
 107          [AC_LANG_SOURCE([
 108             [int main(int argc, char **argv){]
 109             [return argv[argc-1][0];]
 110             [}]])],
 111          AC_MSG_RESULT(yes)
 112          PNG_COPTS="$PNG_COPTS $enable_werror",
 113          AC_MSG_RESULT(no))
 114       CFLAGS="$sav_CFLAGS"
 115     fi],)
 116
 117 # For GCC 5 the default mode for C is -std=gnu11 instead of -std=gnu89
 118 # In pngpriv.h we request just the POSIX 1003.1 and C89 APIs by defining _POSIX_SOURCE to 1
 119 # This is incompatible with the new default mode, so we test for that and force the
 120 # "-std=c89" compiler option:
 121 AC_MSG_CHECKING([if we need to force back C standard to C89])
 122 AC_COMPILE_IFELSE(
 123    [AC_LANG_PROGRAM([
 124       [#define _POSIX_SOURCE 1]
 125       [#include <stdio.h>]
 126    ])],
 127    AC_MSG_RESULT(no),[
 128       if test "x$GCC" != "xyes"; then
 129          AC_MSG_ERROR(
 130             [Forcing back to C89 is required but the flags are only known for GCC])
 131       fi
 132    AC_MSG_RESULT(yes)
 133    CFLAGS="$CFLAGS -std=c89"
 134 ])
 135
 136 # Checks for header files.
 137 AC_HEADER_STDC
 138
 139 # Checks for typedefs, structures, and compiler characteristics.
 140 AC_C_CONST
 141 AC_TYPE_SIZE_T
 142 AC_STRUCT_TM
 143 AC_C_RESTRICT
 144
 145 # Checks for library functions.
 146 AC_FUNC_STRTOD
 147 AC_CHECK_FUNCS([pow], , AC_CHECK_LIB(m, pow, , AC_MSG_ERROR(cannot find pow)) )
 148
 149 # Some later POSIX 1003.1 functions are required for test programs, failure here
 150 # is soft (the corresponding test program is not built).
 151 AC_CHECK_FUNC([clock_gettime],,[AC_MSG_WARN([not building timepng])])
 152 AM_CONDITIONAL([HAVE_CLOCK_GETTIME], [test "$ac_cv_func_clock_gettime" = "yes"])
 153
 154 AC_ARG_WITH(zlib-prefix,
 155    AS_HELP_STRING([[[--with-zlib-prefix]]],
 156       [prefix that may have been used in installed zlib]),
 157       [ZPREFIX=${withval}],
 158       [ZPREFIX='z_'])
 159 AC_CHECK_LIB(z, zlibVersion, ,
 160     AC_CHECK_LIB(z, ${ZPREFIX}zlibVersion, , AC_MSG_ERROR(zlib not installed)))
 161
 162 # The following is for pngvalid, to ensure it catches FP errors even on
 163 # platforms that don't enable FP exceptions, the function appears in the math
 164 # library (typically), it's not an error if it is not found.
 165 AC_CHECK_LIB([m], [feenableexcept])
 166 AC_CHECK_FUNCS([feenableexcept])
 167
 168 AC_MSG_CHECKING([if using Solaris linker])
 169 SLD=`$LD --version 2>&1 | grep Solaris`
 170 if test "$SLD"; then
 171     have_solaris_ld=yes
 172     AC_MSG_RESULT(yes)
 173 else
 174     have_solaris_ld=no
 175     AC_MSG_RESULT(no)
 176 fi
 177 AM_CONDITIONAL(HAVE_SOLARIS_LD, test "$have_solaris_ld" = "yes")
 178
 179 AC_MSG_CHECKING([if libraries can be versioned])
 180 # Special case for PE/COFF platforms: ld reports
 181 # support for version-script, but doesn't actually
 182 # DO anything with it.
 183 case $host in
 184 *cygwin* | *mingw32* | *interix* )
 185     have_ld_version_script=no
 186     AC_MSG_RESULT(no)
 187 ;;
 188 * )
 189
 190 if test "$have_solaris_ld" = "yes"; then
 191     GLD=`$LD --help < /dev/null 2>&1 | grep 'M mapfile'`
 192 else
 193     GLD=`$LD --help < /dev/null 2>/dev/null | grep version-script`
 194 fi
 195
 196 if test "$GLD"; then
 197     have_ld_version_script=yes
 198     AC_MSG_RESULT(yes)
 199 else
 200     have_ld_version_script=no
 201     AC_MSG_RESULT(no)
 202     AC_MSG_WARN(*** You have not enabled versioned symbols.)
 203 fi
 204 ;;
 205 esac
 206
 207 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 208
 209 if test "$have_ld_version_script" = "yes"; then
 210     AC_MSG_CHECKING([for symbol prefix])
 211     SYMBOL_PREFIX=`echo "PREFIX=__USER_LABEL_PREFIX__" \
 212                   | ${CPP-${CC-gcc} -E} - 2>&1 \
 213                   | ${EGREP-grep} "^PREFIX=" \
 214                   | ${SED-sed} -e "s:^PREFIX=::" -e "s:__USER_LABEL_PREFIX__::"`
 215     AC_SUBST(SYMBOL_PREFIX)
 216     AC_MSG_RESULT($SYMBOL_PREFIX)
 217 fi
 218
 219 # Substitutions for .in files
 220 AC_SUBST(PNGLIB_VERSION)
 221 AC_SUBST(PNGLIB_MAJOR)
 222 AC_SUBST(PNGLIB_MINOR)
 223 AC_SUBST(PNGLIB_RELEASE)
 224
 225 # Additional arguments (and substitutions)
 226 # Allow the pkg-config directory to be set
 227 AC_ARG_WITH(pkgconfigdir,
 228    AS_HELP_STRING([[[--with-pkgconfigdir]]],
 229       [Use the specified pkgconfig dir (default is libdir/pkgconfig)]),
 230    [pkgconfigdir=${withval}],
 231    [pkgconfigdir='${libdir}/pkgconfig'])
 232
 233 AC_SUBST([pkgconfigdir])
 234 AC_MSG_NOTICE([[pkgconfig directory is ${pkgconfigdir}]])
 235
 236 # Make the *-config binary config scripts optional
 237 AC_ARG_WITH(binconfigs,
 238    AS_HELP_STRING([[[--with-binconfigs]]],
 239       [Generate shell libpng-config scripts as well as pkg-config data]
 240       [@<:@default=yes@:>@]),
 241    [if test "${withval}" = no; then
 242       binconfigs=
 243       AC_MSG_NOTICE([[libpng-config scripts will not be built]])
 244     else
 245       binconfigs='${binconfigs}'
 246     fi],
 247    [binconfigs='${binconfigs}'])
 248 AC_SUBST([binconfigs])
 249
 250 # Support for prefixes to the API function names; this will generate defines
 251 # at the start of the build to rename exported library functions
 252 AC_ARG_WITH(libpng-prefix,
 253    AS_HELP_STRING([[[--with-libpng-prefix]]],
 254       [prefix libpng exported function (API) names with the given value]),
 255    [if test "${withval:-no}" != "no"; then
 256       AC_SUBST([PNG_PREFIX], [${withval}])
 257     fi])
 258 AM_CONDITIONAL([DO_PNG_PREFIX], [test "${with_libpng_prefix:-no}" != "no"])
 259
 260 # Control over what links are made for installed files.  Versioned files are
 261 # always installed, when the following options are turned on corresponding
 262 # unversioned links are also created (normally as symbolic links):
 263 AC_ARG_ENABLE([unversioned-links],
 264    AS_HELP_STRING([[[--enable-unversioned-links]]],
 265       [Installed libpng header files are placed in a versioned subdirectory]
 266       [and installed libpng library (including DLL) files are versioned.]
 267       [If this option is enabled unversioned links will be created pointing to]
 268       [the corresponding installed files.  If you use libpng.pc or]
 269       [libpng-config for all builds you do not need these links, but if you]
 270       [compile programs directly they will typically #include <png.h> and]
 271       [link with -lpng; in that case you need the links.]
 272       [The links can be installed manually using 'make install-header-links']
 273       [and 'make install-library-links' and can be removed using the]
 274       [corresponding uninstall- targets.  If you do enable this option every]
 275       [libpng 'make install' will recreate the links to point to the just]
 276       [installed version of libpng.  The default is to create the links;]
 277       [use --disable-unversioned-links to change this]))
 278
 279 # The AM_CONDITIONAL test is written so that the default is enabled;
 280 # --disable-unversioned-links must be given to turn the option off.
 281 AM_CONDITIONAL([DO_INSTALL_LINKS],[test "$enable_unversioned_links" != "no"])
 282
 283 AC_ARG_ENABLE([unversioned-libpng-pc],
 284    AS_HELP_STRING([[[--enable-unversioned-libpng-pc]]],
 285       [Install the configuration file 'libpng.pc' as a link to the versioned]
 286       [version.  This is done by default - use --disable-unversioned-libpng-pc]
 287       [to change this.]))
 288 AM_CONDITIONAL([DO_INSTALL_LIBPNG_PC],
 289    [test "$enable_unversioned_libpng_pc" != "no"])
 290
 291 AC_ARG_ENABLE([unversioned-libpng-config],
 292    AS_HELP_STRING([[[--enable-unversioned-libpng-config]]],
 293       [Install the configuration file 'libpng-config' as a link to the]
 294       [versioned version.  This is done by default - use]
 295       [--disable-unversioned-libpng-config to change this.]))
 296 AM_CONDITIONAL([DO_INSTALL_LIBPNG_CONFIG],
 297    [test "$enable_unversioned_libpng_config" != "no"])
 298
 299 # HOST SPECIFIC OPTIONS
 300 # =====================
 301 #
 302 # DEFAULT
 303 # =======
 304 #
 305 AC_ARG_ENABLE([hardware-optimizations],
 306    AS_HELP_STRING([[[--enable-hardware-optimizations]]],
 307       [Enable hardware optimizations: =no/off, yes/on:]),
 308    [case "$enableval" in
 309       no|off)
 310          # disable hardware optimization on all systems:
 311          enable_arm_neon=no
 312          AC_DEFINE([PNG_ARM_NEON_OPT], [0],
 313            [Disable ARM_NEON optimizations])
 314          enable_mips_msa=no
 315          AC_DEFINE([PNG_MIPS_MSA_OPT], [0],
 316            [Disable MIPS_MSA optimizations])
 317          enable_powerpc_vsx=no
 318          AC_DEFINE([PNG_POWERPC_VSX_OPT], [0],
 319            [Disable POWERPC VSX optimizations])
 320          enable_intel_sse=no
 321          AC_DEFINE([PNG_INTEL_SSE_OPT], [0],
 322            [Disable INTEL_SSE optimizations])
 323          ;;
 324       *)
 325          # allow enabling hardware optimization on any system:
 326          case "$host_cpu" in
 327             arm*|aarch64*)
 328               enable_arm_neon=yes
 329               AC_DEFINE([PNG_ARM_NEON_OPT], [0],
 330                 [Enable ARM_NEON optimizations])
 331               ;;
 332             mipsel*|mips64el*)
 333               enable_mips_msa=yes
 334               AC_DEFINE([PNG_MIPS_MSA_OPT], [0],
 335                 [Enable MIPS_MSA optimizations])
 336               ;;
 337             i?86|x86_64)
 338               enable_intel_sse=yes
 339               AC_DEFINE([PNG_INTEL_SSE_OPT], [1],
 340                 [Enable Intel SSE optimizations])
 341               ;;
 342             powerpc*|ppc64*)
 343               enable_powerpc_vsx=yes
 344               AC_DEFINE([PNG_POWERPC_VSX_OPT], [2],
 345                 [Enable POWERPC VSX optimizations])
 346               ;;
 347          esac
 348          ;;
 349    esac])
 350
 351 # ARM
 352 # ===
 353 #
 354 # ARM NEON (SIMD) support.
 355
 356 AC_ARG_ENABLE([arm-neon],
 357    AS_HELP_STRING([[[--enable-arm-neon]]],
 358       [Enable ARM NEON optimizations: =no/off, check, api, yes/on:]
 359       [no/off: disable the optimizations; check: use internal checking code]
 360       [(deprecated and poorly supported); api: disable by default, enable by]
 361       [a call to png_set_option; yes/on: turn on unconditionally.]
 362       [If not specified: determined by the compiler.]),
 363    [case "$enableval" in
 364       no|off)
 365          # disable the default enabling on __ARM_NEON__ systems:
 366          AC_DEFINE([PNG_ARM_NEON_OPT], [0],
 367                    [Disable ARM Neon optimizations])
 368          # Prevent inclusion of the assembler files below:
 369          enable_arm_neon=no;;
 370       check)
 371          AC_DEFINE([PNG_ARM_NEON_CHECK_SUPPORTED], [],
 372                    [Check for ARM Neon support at run-time]);;
 373       api)
 374          AC_DEFINE([PNG_ARM_NEON_API_SUPPORTED], [],
 375                    [Turn on ARM Neon optimizations at run-time]);;
 376       yes|on)
 377          AC_DEFINE([PNG_ARM_NEON_OPT], [2],
 378                    [Enable ARM Neon optimizations])
 379          AC_MSG_WARN([--enable-arm-neon: please specify 'check' or 'api', if]
 380             [you want the optimizations unconditionally pass -mfpu=neon]
 381             [to the compiler.]);;
 382       *)
 383          AC_MSG_ERROR([--enable-arm-neon=${enable_arm_neon}: invalid value])
 384    esac])
 385
 386 # Add ARM specific files to all builds where the host_cpu is arm ('arm*') or
 387 # where ARM optimizations were explicitly requested (this allows a fallback if a
 388 # future host CPU does not match 'arm*')
 389
 390 AM_CONDITIONAL([PNG_ARM_NEON],
 391    [test "$enable_arm_neon" != 'no' &&
 392     case "$host_cpu" in
 393       arm*|aarch64*) :;;
 394       *)    test "$enable_arm_neon" != '';;
 395     esac])
 396
 397 # MIPS
 398 # ===
 399 #
 400 # MIPS MSA (SIMD) support.
 401
 402 AC_ARG_ENABLE([mips-msa],
 403    AS_HELP_STRING([[[--enable-mips-msa]]],
 404       [Enable MIPS MSA optimizations: =no/off, check, api, yes/on:]
 405       [no/off: disable the optimizations; check: use internal checking code]
 406       [(deprecated and poorly supported); api: disable by default, enable by]
 407       [a call to png_set_option; yes/on: turn on unconditionally.]
 408       [If not specified: determined by the compiler.]),
 409    [case "$enableval" in
 410       no|off)
 411          # disable the default enabling on __mips_msa systems:
 412          AC_DEFINE([PNG_MIPS_MSA_OPT], [0],
 413                    [Disable MIPS MSA optimizations])
 414          # Prevent inclusion of the assembler files below:
 415          enable_mips_msa=no;;
 416       check)
 417          AC_DEFINE([PNG_MIPS_MSA_CHECK_SUPPORTED], [],
 418                    [Check for MIPS MSA support at run-time]);;
 419       api)
 420          AC_DEFINE([PNG_MIPS_MSA_API_SUPPORTED], [],
 421                    [Turn on MIPS MSA optimizations at run-time]);;
 422       yes|on)
 423          AC_DEFINE([PNG_MIPS_MSA_OPT], [2],
 424                    [Enable MIPS MSA optimizations])
 425          AC_MSG_WARN([--enable-mips-msa: please specify 'check' or 'api', if]
 426             [you want the optimizations unconditionally pass '-mmsa -mfp64']
 427             [to the compiler.]);;
 428       *)
 429          AC_MSG_ERROR([--enable-mips-msa=${enable_mips_msa}: invalid value])
 430    esac])
 431
 432 # Add MIPS specific files to all builds where the host_cpu is mips ('mips*') or
 433 # where MIPS optimizations were explicitly requested (this allows a fallback if a
 434 # future host CPU does not match 'mips*')
 435
 436 AM_CONDITIONAL([PNG_MIPS_MSA],
 437    [test "$enable_mips_msa" != 'no' &&
 438     case "$host_cpu" in
 439       mipsel*|mips64el*) :;;
 440     esac])
 441
 442 # INTEL
 443 # =====
 444 #
 445 # INTEL SSE (SIMD) support.
 446
 447 AC_ARG_ENABLE([intel-sse],
 448    AS_HELP_STRING([[[--enable-intel-sse]]],
 449       [Enable Intel SSE optimizations: =no/off, yes/on:]
 450       [no/off: disable the optimizations;]
 451       [yes/on: enable the optimizations.]
 452       [If not specified: determined by the compiler.]),
 453    [case "$enableval" in
 454       no|off)
 455          # disable the default enabling:
 456          AC_DEFINE([PNG_INTEL_SSE_OPT], [0],
 457                    [Disable Intel SSE optimizations])
 458          # Prevent inclusion of the assembler files below:
 459          enable_intel_sse=no;;
 460       yes|on)
 461          AC_DEFINE([PNG_INTEL_SSE_OPT], [1],
 462                    [Enable Intel SSE optimizations]);;
 463       *)
 464          AC_MSG_ERROR([--enable-intel-sse=${enable_intel_sse}: invalid value])
 465    esac])
 466
 467 # Add Intel specific files to all builds where the host_cpu is Intel ('x86*')
 468 # or where Intel optimizations were explicitly requested (this allows a
 469 # fallback if a future host CPU does not match 'x86*')
 470 AM_CONDITIONAL([PNG_INTEL_SSE],
 471    [test "$enable_intel_sse" != 'no' &&
 472     case "$host_cpu" in
 473       i?86|x86_64) :;;
 474       *)    test "$enable_intel_sse" != '';;
 475     esac])
 476
 477 # PowerPC
 478 # ===
 479 #
 480 # PowerPC VSX (SIMD) support.
 481
 482 AC_ARG_ENABLE([powerpc-vsx],
 483 AS_HELP_STRING([[[--enable-powerpc-vsx]]],
 484       [Enable POWERPC VSX optimizations: =no/off, check, api, yes/on:]
 485       [no/off: disable the optimizations; check: use internal checking code]
 486       [api: disable by default, enable by a call to png_set_option]
 487       [yes/on: turn on unconditionally.]
 488       [If not specified: determined by the compiler.]),
 489    [case "$enableval" in
 490       no|off)
 491          # disable the default enabling on __ppc64__ systems:
 492          AC_DEFINE([PNG_POWERPC_VSX_OPT], [0],
 493                    [Disable POWERPC VSX optimizations])
 494          # Prevent inclusion of the platform specific files below:
 495          enable_powerpc_vsx=no;;
 496       check)
 497          AC_DEFINE([PNG_POWERPC_VSX_CHECK_SUPPORTED], [],
 498                    [Check for POWERPC VSX support at run-time])
 499          AC_MSG_WARN([--enable-powerpc-vsx Please check contrib/powerpc/README file]
 500             [for the list of supported OSes.]);;
 501       api)
 502          AC_DEFINE([PNG_POWERPC_VSX_API_SUPPORTED], [],
 503                    [Turn on POWERPC VSX optimizations at run-time]);;
 504       yes|on)
 505          AC_DEFINE([PNG_POWERPC_VSX_OPT], [2],
 506                    [Enable POWERPC VSX optimizations])
 507          AC_MSG_WARN([--enable-powerpc-vsx: please specify 'check' or 'api', if]
 508             [you want the optimizations unconditionally pass '-maltivec -mvsx']
 509             [or '-mcpu=power8'to the compiler.]);;
 510       *)
 511          AC_MSG_ERROR([--enable-powerpc-vsx=${enable_powerpc_vsx}: invalid value])
 512    esac])
 513
 514 # Add PowerPC specific files to all builds where the host_cpu is powerpc('powerpc*') or
 515 # where POWERPC optimizations were explicitly requested (this allows a fallback if a
 516 # future host CPU does not match 'powerpc*')
 517
 518 AM_CONDITIONAL([PNG_POWERPC_VSX],
 519    [test "$enable_powerpc_vsx" != 'no' &&
 520     case "$host_cpu" in
 521       powerpc*|ppc64*) :;;
 522     esac])
 523
 524
 525 AC_MSG_NOTICE([[Extra options for compiler: $PNG_COPTS]])
 526
 527 # Config files, substituting as above
 528 AC_CONFIG_FILES([Makefile libpng.pc:libpng.pc.in])
 529 AC_CONFIG_FILES([libpng-config:libpng-config.in],
 530    [chmod +x libpng-config])
 531
 532 AC_OUTPUT