conky/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: James Rayner <james@archlinux.org>
   5 # Contributor: Partha Chowdhury <kira.laucas@gmail.com>
   6
   7 pkgname=conky
   8 pkgver=1.18.1
   9 _gitcommit=a21a8f7d26f07f1dc5c144be2120e8bc6721159f
  10 pkgrel=1
  11 pkgdesc='Lightweight system monitor for X'
  12 url='https://github.com/brndnmtthws/conky'
  13 license=('BSD' 'GPL')
  14 arch=('x86_64')
  15 makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git' 'catch2' 'pandoc' 'python-yaml' 'python-jinja')
  16 depends=(
  17   'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
  18   'libxml2' 'libpulse' 'libxnvctrl' 'systemd-libs' 'ncurses' 'curl'
  19   libncursesw.so libXNVCtrl.so libsystemd.so libpulse.so libcurl.so)
  20 #source=("git+https://github.com/brndnmtthws/conky.git#commit=${_gitcommit}?signed")
  21 #v1.17.0 commit not signed
  22 source=("git+https://github.com/brndnmtthws/conky.git#tag=v$pkgver?signed")
  23 sha512sums=('SKIP')
  24 b2sums=('SKIP')
  25 validpgpkeys=(
  26   'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
  27 )
  28
  29 pkgver() {
  30   cd ${pkgname}
  31   git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  32 }
  33
  34 prepare() {
  35   cd $pkgname
  36 # Unbundle catch2 to fix build with glibc 2.35
  37   rm -r tests/catch2
  38   ln -s /usr/include/catch2 tests
  39 }
  40
  41 build() {
  42   cd ${pkgname}
  43   cmake \
  44     -B build \
  45     -D CMAKE_BUILD_TYPE=Release \
  46     -D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
  47     -D MAINTAINER_MODE=OFF \
  48     -D BUILD_TESTS=ON \
  49     -D BUILD_DOCS=ON \
  50     -D BUILD_EXTRAS=ON \
  51     -D BUILD_WLAN=ON \
  52     -D BUILD_XDBE=ON \
  53     -D BUILD_XSHAPE=ON \
  54     -D BUILD_IMLIB2=ON \
  55     -D BUILD_CURL=ON \
  56     -D BUILD_RSS=ON \
  57     -D BUILD_NVIDIA=ON \
  58     -D BUILD_PULSEAUDIO=ON \
  59     -D BUILD_JOURNAL=ON \
  60     -D CMAKE_INSTALL_PREFIX=/usr \
  61     -Wno-dev \
  62     -S .
  63
  64   make -C build
  65 }
  66
  67 package() {
  68   cd ${pkgname}
  69   make -C build DESTDIR="${pkgdir}" install
  70   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  71   install -Dm 644 build/extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
  72   install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
  73 }
  74
  75 # vim: ts=2 sw=2 et: