ghex/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias@justdreams.de>
   4
   5 pkgbase=ghex
   6 pkgname=(ghex ghex-docs)
   7 pkgver=43.0
   8 pkgrel=1
   9 pkgdesc="A simple binary editor for the Gnome desktop"
  10 url="https://wiki.gnome.org/Apps/Ghex"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(libadwaita)
  14 makedepends=(git meson yelp-tools gobject-introspection gi-docgen)
  15 options=(debug)
  16 _commit=2975e977301e44632a2718fb9a74d5f99fdd881f  # tags/43.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/ghex.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd ghex
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd ghex
  27 }
  28
  29 build() {
  30   arch-meson ghex build -D gtk_doc=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package_ghex() {
  39   provides=(libgtkhex-4.so)
  40   groups=(gnome-extra)
  41
  42   meson install -C build --destdir "$pkgdir"
  43
  44   mkdir -p doc/usr/share
  45   mv {"$pkgdir",doc}/usr/share/doc
  46 }
  47
  48 package_ghex-docs() {
  49   pkgdesc+=" (documentation)"
  50   depends=()
  51
  52   mv doc/* "$pkgdir"
  53 }
  54
  55 # vim:set sw=2 sts=-1 et: