graphene/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=graphene
   4 pkgver=1.10.8
   5 pkgrel=1
   6 pkgdesc="A thin layer of graphic data types"
   7 url="https://ebassi.github.io/graphene/"
   8 arch=(x86_64)
   9 license=(MIT)
  10 makedepends=(git gtk-doc gobject-introspection meson glib2)
  11 checkdepends=(python-gobject python-tappy)
  12 options=(debug)
  13 _commit=4e2578450809c2099400cf85caf18eafcd7100aa  # tags/1.10.8^0
  14 source=("git+https://github.com/ebassi/graphene#commit=$_commit"
  15         "git+https://github.com/ebassi/mutest"
  16         no-installed-tests.diff)
  17 sha256sums=('SKIP'
  18             'SKIP'
  19             'fd7c41b25920077158d7de77f5d073e3a5a215c4d96c3b9bd016ffda615be4c4')
  20
  21 pkgver() {
  22   cd graphene
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd graphene
  28
  29   # Don't install tests
  30   git apply -3 ../no-installed-tests.diff
  31
  32   git submodule init
  33   git submodule set-url subprojects/mutest "$srcdir/mutest"
  34   git submodule update
  35 }
  36
  37 build() {
  38   arch-meson graphene build \
  39     -D gtk_doc=true \
  40     -D installed_tests=false
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   depends=(libg{lib,object}-2.0.so)
  50   provides=(libgraphene-1.0.so)
  51
  52   meson install -C build --destdir "$pkgdir"
  53   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 graphene/LICENSE.txt
  54 }
  55
  56 # vim:set sw=2 et: