xfce4-cpugraph-plugin/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3 # Contributor: Aurelien Foret <orelien@chez.com>
   4
   5 pkgname=xfce4-cpugraph-plugin
   6 pkgver=1.2.7
   7 pkgrel=1
   8 pkgdesc="Graphical representation of the CPU load"
   9 arch=('x86_64')
  10 license=('GPL' 'custom')
  11 url="https://docs.xfce.org/panel-plugins/xfce4-cpugraph-plugin"
  12 groups=('xfce4-goodies')
  13 depends=('xfce4-panel')
  14 makedepends=('intltool')
  15 source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  16 sha256sums=('68a651e278ed7186964e455b69b15da77f8d56257e5c3d6adf783b3ee9337405')
  17
  18 build() {
  19   cd $pkgname-$pkgver
  20
  21   ./configure \
  22     --prefix=/usr \
  23     --sysconfdir=/etc \
  24     --localstatedir=/var \
  25     --disable-debug
  26   make
  27 }
  28
  29 package() {
  30   cd $pkgname-$pkgver
  31   make DESTDIR="$pkgdir" install
  32   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  33 }
  34
  35 # vim:set ts=2 sw=2 et: