dconf-editor/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=dconf-editor
   4 pkgver=3.38.3
   5 pkgrel=2
   6 pkgdesc="GSettings editor for GNOME"
   7 url="https://wiki.gnome.org/Apps/DconfEditor"
   8 arch=(x86_64)
   9 license=(GPL3)
  10 groups=(gnome-extra)
  11 depends=(gtk3 dconf)
  12 makedepends=(vala meson git)
  13 options=(debug)
  14 _commit=886181423ba8e93e766087425a0f2066f450cab1  # tags/3.38.3^0
  15 source=("git+https://gitlab.gnome.org/GNOME/dconf-editor.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25
  26   # https://bugs.archlinux.org/task/75459
  27   git cherry-pick -n 56474378568e6ff4af8aa912810323e808c1d977
  28 }
  29
  30 build() {
  31   arch-meson $pkgname build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: