glu/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: Laurent Carlier <lordheavym@gmail.com>
   3
   4 pkgname=glu
   5 pkgver=9.0.2
   6 pkgrel=3
   7 pkgdesc="Mesa OpenGL utility library"
   8 arch=('x86_64')
   9 url="https://gitlab.freedesktop.org/mesa/glu"
  10 license=('LGPL')
  11 depends=('libgl')
  12 makedepends=('meson')
  13 options=('debug')
  14 source=(https://mesa.freedesktop.org/archive/glu/glu-$pkgver.tar.xz{,.sig}
  15         0001-pkgconfig-Depend-on-opengl-when-built-with-libglvnd.patch
  16         0002-pkgconfig-Drop-unneeded-lines-from-autotools-build.patch
  17         0003-pkgconfig-meson-build-should-match-autotools-require.patch)
  18 sha512sums=('2517d7406bb643d12c017a95dcb5d8716f307344332638bcbdf274a90752a7c22165d34745f1b082ed916bb07d40e62d1d1d67d96426225be63166f3480d6f64'
  19             'SKIP'
  20             'c6fe65e9505c37f94f6c136dc1ad5aac62828bb0d60d7cf887743521ba030b64c63111713c54c77480b79d9fa0fe9424074c59b391ec385b6ed2867cf03e5128'
  21             '132184fd813c20a5dcd5357bb651e42f9df9bd8ed5d6cfe60e0956d74854863210bdf5a498f5f0c60122cafb34389bc4c4d288c66d793c4be11ab25781c44881'
  22             '972518b5363c7768655ae7a18d31faf42ebeae8be3408edbebbe021b17300cec366b091b82c880422052ba469ec6569ecb07b0741b2560822c578e13dce8c098')
  23 validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # "Matt Turner <mattst88@gmail.com>"
  24
  25 prepare() {
  26   cd glu-$pkgver
  27
  28   # merged upstream
  29   patch -Np1 -i ../0001-pkgconfig-Depend-on-opengl-when-built-with-libglvnd.patch
  30   patch -Np1 -i ../0002-pkgconfig-Drop-unneeded-lines-from-autotools-build.patch
  31   patch -Np1 -i ../0003-pkgconfig-meson-build-should-match-autotools-require.patch
  32 }
  33
  34 build() {
  35   arch-meson glu-$pkgver build \
  36     -D default_library=shared
  37
  38   # Print config
  39   meson configure build
  40
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50 }