efivar/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
   4
   5 pkgname=efivar
   6 pkgdesc="Tools and libraries to work with EFI variables"
   7 pkgver=38
   8 pkgrel=2
   9 arch=(x86_64)
  10 url="https://github.com/rhboot/efivar"
  11 license=(LGPL2.1)
  12 depends=(glibc)
  13 makedepends=(git mandoc)
  14 checkdepends=(grub)
  15 provides=(libefiboot.so libefisec.so libefivar.so)
  16 # LTO has the linker segfaulting with binutils < 2.38.0: https://github.com/rhboot/efivar/issues/196
  17 options=(!lto)
  18 source=(
  19   "git+https://github.com/rhinstaller/efivar.git#tag=${pkgver}?signed"
  20   "${pkgname}-38-ld_t.patch::https://github.com/rhboot/efivar/pull/201/commits/197a0874ea4010061b98b4b55eff65b33b1cd741.patch"
  21 )
  22 sha512sums=('SKIP'
  23             '568bc88b182875c37479c49b3dbf5b8ee6edf8090f940176e67c9aa28dd2ff6f417c70b2bef6b5df99ada2afa33db3efd295ba9de5d68b3ecc5ce1dc3361d042')
  24 b2sums=('SKIP'
  25         'ccddc04ab83d4dcf570d5a89e43fc27d36e2010513b36d9eb2fcdea71ceb5dba96a064a1cbca9ffdecf17fb5b9cb22cfe89eae4ee3a188547a4ab6fa6b4e2983')
  26 validpgpkeys=('B00B48BC731AA8840FED9FB0EED266B70F4FEF10') # Peter Jones <pjones@redhat.com>
  27
  28 prepare() {
  29   cd "${pkgname}"
  30   # fix issues with linker scripts: https://github.com/rhboot/efivar/pull/201
  31   patch -Np1 -i ../"${pkgname}-38-ld_t.patch"
  32 }
  33
  34 build() {
  35   # disable -Werror by default by setting ERRORS to empty string
  36   make ERRORS='' all -C "${pkgname}"
  37 }
  38
  39 check() {
  40   make GRUB_PREFIX=grub test -k -C "${pkgname}" || echo "grub related tests are flaky"
  41 }
  42
  43 package() {
  44   make DESTDIR="${pkgdir}/" \
  45        libdir=/usr/lib/ \
  46        bindir=/usr/bin/ \
  47        mandir=/usr/share/man/ \
  48        includedir=/usr/include/ \
  49        install -j1 V=1 \
  50        -C "${pkgname}"
  51   install -vDm 644 "${pkgname}/"{README.md,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
  52 }