gnome-documents/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-documents
   4 pkgver=3.34.0+34+g678141fa
   5 pkgrel=1
   6 pkgdesc="A document manager application for GNOME"
   7 url="https://wiki.gnome.org/Apps/Documents"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(evince gjs gtk3 gnome-desktop gnome-online-accounts libgdata
  11          tracker-miners libzapojit webkit2gtk gnome-online-miners librsvg
  12          libgepub gnome-epub-thumbnailer)
  13 makedepends=(gobject-introspection git meson yelp-tools inkscape)
  14 optdepends=('libreoffice-fresh: Support for Libreoffice document types')
  15 groups=(gnome-extra)
  16 _commit=678141fa4cdce0af0baccff965c27734b0c4546b  # master
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-documents.git#commit=$_commit"
  18         "git+https://gitlab.gnome.org/GNOME/libgd.git"
  19         0001-getting-started-Fix-the-build-with-inkscape-1.0.patch)
  20 sha256sums=('SKIP'
  21             'SKIP'
  22             '9c7dea42e61b179c780795ae3441ec92a06d5660242649f39aaf441d0b1bb6c0')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31
  32   # https://bugs.archlinux.org/task/67942
  33   git apply -3 ../0001-getting-started-Fix-the-build-with-inkscape-1.0.patch
  34
  35   git submodule init
  36   git submodule set-url subprojects/libgd "$srcdir/libgd"
  37   git submodule update
  38 }
  39
  40
  41 build() {
  42   arch-meson $pkgname build -D getting_started=true
  43   meson compile -C build
  44 }
  45
  46 check() {
  47   meson test -C build --print-errorlogs
  48 }
  49
  50 package() {
  51   meson install -C build --destdir "$pkgdir"
  52 }
  53
  54 # vim:set sw=2 et: