zbar/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Marti Raudsepp <marti@juffo.org>
   3 # Contributor: Radu Andries <admiral0@tuxfamily.org>
   4 # Contributor: Andy Weidenbaum <archbaum@gmail.com>
   5
   6 pkgname=zbar
   7 pkgver=0.23.90
   8 pkgrel=1
   9 pkgdesc="Application and library for reading bar codes from various sources"
  10 arch=('x86_64')
  11 url="https://github.com/mchehab/zbar"
  12 license=('LGPL')
  13 depends=('dbus' 'imagemagick' 'libsm' 'libxv' 'v4l-utils')
  14 makedepends=('gtk3' 'qt5-x11extras' 'python' 'xmlto' 'docbook-xsl' 'gobject-introspection')
  15 optdepends=('gtk3: for zbar-gtk'
  16             'qt5-x11extras: for zbar-qt'
  17             'python: for zbar python bindings')
  18 conflicts=('zbar-gtk' 'zbar-qt' 'python-zbar')
  19 provides=('zbar-gtk' 'zbar-qt' 'python-zbar')
  20 replaces=('zbar-gtk' 'zbar-qt' 'python-zbar')
  21 source=("$pkgname-$pkgver.tar.gz::https://github.com/mchehab/zbar/archive/$pkgver.tar.gz")
  22 sha512sums=('d73d71873bec68ee021997512a9edbd223f5f5fe43c66c4dd3502224ba6009be2e5e1714766cb8e1056244673e87e0939ed0319116f61d7371b5ab79fb5e04eb')
  23
  24 prepare() {
  25   cd zbar-$pkgver
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd zbar-$pkgver
  31   ./configure --prefix=/usr --with-qt --with-gtk=gtk3 --with-dbusconfdir=/usr/share CFLAGS="$CFLAGS -DNDEBUG"
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33   make
  34 }
  35
  36 package() {
  37   cd zbar-$pkgver
  38   make DESTDIR="$pkgdir" install
  39 }
  40
  41 # vim:set ts=2 sw=2 et: