libao/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: dorphell <dorphell@archlinux.org>
   4
   5 pkgname=libao
   6 pkgver=1.2.2
   7 pkgrel=5
   8 pkgdesc="Cross-platform audio output library and plugins"
   9 url="https://xiph.org/ao/"
  10 arch=('x86_64')
  11 license=('GPL2')
  12 depends=('gcc-libs' 'glibc')
  13 makedepends=('alsa-lib' 'libpulse')
  14 provides=('libao.so')
  15 backup=("etc/${pkgname}.conf")
  16 source=("https://gitlab.xiph.org/xiph/libao/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
  17         "${pkgname}.conf")
  18 sha512sums=('d2736d25b60862e7d7469611ce31b1df40a4366ab160e2ff1b46919ae91692d1596c8468e4f016303b306fc3ac1bddc7b727f535a362f403c3fe7c6532e9045a'
  19             'f50d23993eeab4786e68edec88665783a697c141e8f26d38edbe4deb1c760ec690741c70f39e1ec5edaf07ce18216709ea8c23bd622543796248408ce32e53c4')
  20 b2sums=('e5b5d87c4357ee113769732cb6a7e0afa28b2bc4923be8dacd1fa39ac5fb96d8a5e19bc45137ffc8ec63eef0382130ab9b311aad3a66be4566e0cb9761417b23'
  21         '5ace51c34b8f9409c5f322ccb1381984b35402866ced3b1b38b2b8fffd10780de80d33418e031decb2cfba452029a48b40df8077d7d67390fcf87bcf57c0cbca')
  22
  23 prepare() {
  24   cd "${pkgname}-${pkgver}"
  25   autoreconf -vfi
  26 }
  27
  28 build() {
  29   cd "${pkgname}-${pkgver}"
  30   ./configure --prefix=/usr \
  31               --enable-alsa-mmap
  32   make
  33 }
  34
  35 package() {
  36   depends+=('libasound.so' 'libpulse.so' 'libpulse-simple.so')
  37   cd "${pkgname}-${pkgver}"
  38   make DESTDIR="${pkgdir}" install
  39   # default config
  40   install -vDm 644 "../${pkgname}.conf" -t "${pkgdir}/etc/"
  41   install -vDm 644 {AUTHORS,CHANGES,HACKING,README,TODO} \
  42     -t "${pkgdir}/usr/share/doc/${pkgname}"
  43 }