rtkit/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   3
   4 pkgname=rtkit
   5 pkgver=0.13
   6 pkgrel=2
   7 pkgdesc="Realtime Policy and Watchdog Daemon"
   8 url="https://github.com/heftig/rtkit"
   9 arch=(x86_64)
  10 license=(GPL3 custom:BSD)
  11 depends=(dbus polkit systemd)
  12 makedepends=(git meson vim)
  13 _commit=b9169402fe5e82d20efb754509eb0b191f214599  # tags/v0.13^0
  14 source=("git+https://github.com/heftig/rtkit?signed#commit=$_commit")
  15 sha256sums=('SKIP')
  16 validpgpkeys=('8218F88849AAC522E94CF470A5E9288C4FA415FA')  # Jan Alexander Steffens (heftig)
  17
  18 pkgver() {
  19   cd rtkit
  20   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd rtkit
  25 }
  26
  27 build() {
  28   arch-meson rtkit build -D installed_tests=false
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   meson install -C build --destdir "$pkgdir"
  37
  38   echo 'u rtkit 133 "RealtimeKit" /proc' |
  39     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/rtkit.conf"
  40
  41   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 rtkit/LICENSE
  42   sed -ne '4,25p' rtkit/rtkit.c |
  43     install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  44 }