xf86-input-wacom/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4 # Contributor: M Rawash <mrawash@gmail.com>
   5
   6 pkgname=xf86-input-wacom
   7 pkgver=1.1.0
   8 pkgrel=1
   9 pkgdesc="X.Org Wacom tablet driver"
  10 arch=(x86_64)
  11 url="https://github.com/linuxwacom/xf86-input-wacom"
  12 license=(GPL)
  13 depends=(libxi libxinerama libxrandr systemd-libs)
  14 makedepends=('xorg-server-devel' 'X-ABI-XINPUT_VERSION=24.4' 'meson'
  15         'gobject-introspection'
  16         # for tests
  17         'python-libevdev' 'python-pytest' 'python-yaml' 'python-gobject' 'attr')
  18 conflicts=('xorg-server<21.1.1' 'X-ABI-XINPUT_VERSION<24' 'X-ABI-XINPUT_VERSION>=25')
  19 source=(https://github.com/linuxwacom/xf86-input-wacom/releases/download/$pkgname-$pkgver/$pkgname-$pkgver.tar.bz2{,.sig})
  20 # check at https://github.com/linuxwacom/xf86-input-wacom/releases
  21 sha256sums=('23b674067f344de22bcbb4bac885c43df54c5e841f6dade7c9d18ba7ce297a12'
  22             'SKIP')
  23 #validpgpkeys=('9A12ECCC5383CA2AF5B42CDCA6DC66911B2127D5') # Jason Gerecke <killertofu@gmail.com>
  24 validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') #  "Peter Hutterer (Who-T) <office@who-t.net>"
  25 #validpgpkeys=('5222AA87620F928D2C16F62BDB4ABF7C3424190B') # "Aaron Armstrong Skomra <skomra@gmail.com>"
  26 #validpgpkeys=('FBE078781106933D3DDCF93E5B4EA609784983CA') # "Jason Gerecke <jason.gerecke@wacom.com>"
  27
  28 build() {
  29   arch-meson $pkgname-$pkgver build \
  30     -D xorg-conf-dir=/usr/share/X11/xorg.conf.d/ \
  31     -D systemd-unit-dir=/usr/lib/systemd/system/ \
  32     -D unittests=enabled
  33
  34   # Print config
  35   meson configure build
  36   ninja -C build
  37 }
  38
  39 check() {
  40   meson test -C build # || /bin/true
  41 }
  42
  43 package() {
  44   DESTDIR="$pkgdir" ninja -C build install
  45 }