python-attrs/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgbase=python-attrs
   4 pkgname=('python-attrs' 'python2-attrs')
   5 pkgver=21.2.0
   6 pkgrel=3
   7 pkgdesc="Attributes without boilerplate."
   8 arch=('any')
   9 license=('MIT')
  10 url="https://attrs.readthedocs.org/"
  11 makedepends=('python-setuptools' 'python2-setuptools')
  12 checkdepends=('python-pytest-runner' 'python-zope-interface' 'python-hypothesis')
  13 source=("https://pypi.io/packages/source/a/attrs/attrs-$pkgver.tar.gz")
  14 sha512sums=('35863f599076357e40f72a62968f4a2f9bc2af9f59f484fef051be4f9730ce9e28e11568915d690ade7980df8998af22e2ff8b9568a205d7745e246ba5f3a7e1')
  15
  16 prepare() {
  17   cp -a attrs-$pkgver{,-py2}
  18 }
  19
  20 build() {
  21   cd "$srcdir"/attrs-$pkgver
  22   python setup.py build
  23
  24   cd "$srcdir"/attrs-$pkgver-py2
  25   python2 setup.py build
  26 }
  27
  28 check() {
  29   cd attrs-$pkgver
  30   python setup.py pytest
  31 }
  32
  33 package_python-attrs() {
  34   depends=('python')
  35
  36   cd attrs-$pkgver
  37   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  38   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  39 }
  40
  41 package_python2-attrs() {
  42   depends=('python2')
  43
  44   cd attrs-$pkgver-py2
  45   python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
  46   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  47 }