bullet/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
   2 # Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>
   3
   4 pkgbase=bullet
   5 pkgname=('bullet' 'bullet-docs' 'python-pybullet')
   6 pkgver=3.17
   7 pkgrel=1
   8 pkgdesc="A 3D Collision Detection and Rigid Body Dynamics Library for games and animation"
   9 arch=('x86_64')
  10 url="http://www.bulletphysics.com/Bullet/"
  11 license=('custom:zlib')
  12 makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'glu' 'python' 'python-numpy' 'python-setuptools' 'ninja')
  13 source=("$pkgname-$pkgver.tar.gz::https://github.com/bulletphysics/bullet3/archive/${pkgver}.tar.gz"
  14         bullet3_examplebrowser.sh)
  15 sha512sums=('a5105bf5f1dd365a64a350755c7d2c97942f74897a18dcdb3651e6732fd55cc1030a096f5808cf50575281f05e3ac09aa50a48d271a47b94cd61f5167a72b7cc'
  16             '8741ad94b6c46c226d89aebc8ab06d8a11bac3c04d3f0a2bf7a7524792a3375aa7bf7d295410b16fbeb4c348a31057b4570acdebe9bbaea251f44daca8d9fe81')
  17
  18 prepare() {
  19   cd bullet3-${pkgver}
  20   sed -i '/SET_TARGET_PROPERTIES(pybullet PROPERTIES PREFIX/d' examples/pybullet/CMakeLists.txt
  21 }
  22
  23 build() {
  24   cd bullet3-${pkgver}
  25
  26   cmake . \
  27       -Bbuild \
  28       -GNinja \
  29       -DCMAKE_INSTALL_PREFIX=/usr \
  30       -DBUILD_SHARED_LIBS=1 \
  31       -DINSTALL_LIBS=1 \
  32       -DINSTALL_EXTRA_LIBS=1 \
  33       -DBUILD_PYBULLET=ON \
  34       -DBUILD_PYBULLET_NUMPY=ON \
  35       -DBUILD_OPENGL3_DEMOS=ON \
  36       -DCMAKE_BUILD_TYPE=Release \
  37       -DCMAKE_SKIP_RPATH=YES
  38
  39   ninja -C build
  40
  41   python setup.py build
  42   doxygen
  43 }
  44
  45 package_bullet() {
  46   optdepends=('glu: for the example browser'
  47               'python: python bindings'
  48               'python-numpy: python bindings'
  49               'bullet-docs: documentation')
  50
  51   cd bullet3-${pkgver}
  52
  53   DESTDIR="${pkgdir}" ninja -C build install
  54
  55   cd build
  56
  57   install -Dm755 examples/ExampleBrowser/libBulletExampleBrowserLib.so.${pkgver} "${pkgdir}"/usr/lib/libBulletExampleBrowserLib.so.${pkgver}
  58   install -Dm755 examples/OpenGLWindow/libOpenGLWindow.so "${pkgdir}"/usr/lib/libOpenGLWindow.so
  59   install -Dm755 examples/ThirdPartyLibs/Gwen/libgwen.so "${pkgdir}"/usr/lib/libgwen.so
  60   install -Dm755 examples/ThirdPartyLibs/BussIK/libBussIK.so "${pkgdir}"/usr/lib/libBussIK.so
  61   install -Dm755 "${srcdir}"/bullet3_examplebrowser.sh "${pkgdir}"/usr/bin/bullet3_examplebrowser
  62   install -Dm755 examples/ExampleBrowser/App_ExampleBrowser "${pkgdir}"/opt/bullet/App_ExampleBrowser
  63   cp -r data "${pkgdir}"/opt/bullet/
  64
  65   install -Dm644 ../LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgbase}/LICENSE
  66 }
  67
  68 package_python-pybullet() {
  69   pkgdesc="Bullet Python bindings"
  70   depends+=('bullet' 'gcc-libs')
  71
  72   cd bullet3-${pkgver}
  73
  74   install -Dm755 build/examples/pybullet/libpybullet.so.${pkgver} "${pkgdir}"/usr/lib/libpybullet.so.${pkgver}
  75   python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
  76
  77   install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  78 }
  79
  80 package_bullet-docs() {
  81   pkgdesc="Documentation for bullet"
  82
  83   cd bullet3-${pkgver}
  84
  85   # install docs
  86   install -Dm644 docs/GPU_rigidbody_using_OpenCL.pdf "${pkgdir}"/usr/share/doc/bullet/GPU_rigidbody_using_OpenCL.pdf
  87   install -Dm644 docs/Bullet_User_Manual.pdf "${pkgdir}"/usr/share/doc/bullet/Bullet_User_Manual.pdf
  88   install -Dm644 docs/BulletQuickstart.pdf "${pkgdir}"/usr/share/doc/bullet/BulletQuickstart.pdf
  89   cp -r html "${pkgdir}"/usr/share/doc/bullet/html
  90 }
  91 # vim: sw=2 ts=2 et: