fribidi/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Nezmer <Nezmer@gmail.com>
   4
   5 pkgname=fribidi
   6 pkgver=1.0.11
   7 pkgrel=1
   8 pkgdesc="A Free Implementation of the Unicode Bidirectional Algorithm"
   9 url="https://github.com/fribidi/fribidi/"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glibc)
  13 makedepends=(git meson)
  14 provides=(libfribidi.so)
  15 _commit=247fddc3599e3fe7b1b5cc21020c9eb51e662637  # tags/v1.0.11^0
  16 source=("git+https://github.com/fribidi/fribidi#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd fribidi
  21   git describe --tags | sed -e 's/-/+/g' -e 's/^v//'
  22 }
  23
  24 prepare() {
  25   cd fribidi
  26 }
  27
  28 build() {
  29   arch-meson fribidi build \
  30     -D docs=false
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40 }
  41
  42 # vim:set sw=2 et: