graphene/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=graphene
   4 pkgver=1.10.6
   5 pkgrel=1
   6 pkgdesc="A thin layer of graphic data types"
   7 url="https://ebassi.github.io/graphene/"
   8 arch=(x86_64)
   9 license=(MIT)
  10 makedepends=(git gtk-doc gobject-introspection meson glib2)
  11 checkdepends=(python-gobject python-tappy)
  12 _commit=01c1b63e98c9191093880919fe6a8c4327515756  # tags/1.10.6^0
  13 source=("git+https://github.com/ebassi/graphene#commit=$_commit"
  14         "git+https://github.com/ebassi/mutest")
  15 sha256sums=('SKIP'
  16             'SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25
  26   git submodule init
  27   git config --local submodule.subprojects/mutest.url "$srcdir/mutest"
  28   git submodule update
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build \
  33     -D gtk_doc=true \
  34     -D installed_tests=false
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   meson test -C build --print-errorlogs
  40 }
  41
  42 package() {
  43   depends=(libg{lib,object}-2.0.so)
  44   provides=(libgraphene-1.0.so)
  45
  46   DESTDIR="$pkgdir" meson install -C build
  47   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/LICENSE.txt
  48 }
  49
  50 # vim:set sw=2 et: