ocl-icd/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2 # Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
   3
   4 pkgname=ocl-icd
   5 pkgver=2.3.1
   6 pkgrel=1
   7 pkgdesc="OpenCL ICD Bindings"
   8 arch=('x86_64')
   9 url="https://github.com/OCL-dev/ocl-icd"
  10 license=('BSD')
  11 depends=('glibc')
  12 makedepends=('ruby' 'mesa' 'xmlto' 'asciidoc' 'opencl-headers>=2.1')
  13 checkdepends=()
  14 provides=('opencl-icd-loader')
  15 conflicts=('libcl')
  16 replaces=('libcl')
  17 optdepends=('opencl-driver: packaged opencl driver')
  18 source=("ocl-icd-${pkgver}.tar.gz::https://github.com/OCL-dev/${pkgname}/archive/v${pkgver}.tar.gz")
  19 sha256sums=('a32b67c2d52ffbaf490be9fc18b46428ab807ab11eff7664d7ff75e06cfafd6d')
  20
  21 prepare() {
  22   cd "$srcdir/$pkgname-$pkgver"
  23   autoreconf -fiv
  24 }
  25
  26 build() {
  27   cd "$srcdir/$pkgname-$pkgver"
  28   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  29   ./configure --prefix=/usr
  30   make
  31 }
  32
  33 check() {
  34   cd "$srcdir/$pkgname-$pkgver"
  35   make -k check
  36 }
  37
  38 package() {
  39   cd "$srcdir/$pkgname-$pkgver"
  40   make DESTDIR="$pkgdir/" install
  41
  42   install -m755 -d "$pkgdir/usr/share/licenses/ocl-icd"
  43   install -m644 "$srcdir/$pkgname-$pkgver/COPYING" "${pkgdir}/usr/share/licenses/ocl-icd/"
  44 }
  45
  46 # vim:set ts=2 sw=2 et: