libedit/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
   4 # Contributor: Roman Cheplyaka <roma@ro-che.info>
   5
   6 pkgname=libedit
   7 _pkgver=20210910-3.1
   8 pkgver=${_pkgver/-/_}
   9 pkgrel=1
  10 pkgdesc='Command line editor library providing generic line editing, history, and tokenization functions'
  11 url='https://thrysoee.dk/editline/'
  12 arch=('x86_64')
  13 license=('BSD')
  14 depends=('glibc' 'ncurses' 'libncursesw.so')
  15 provides=('libedit.so')
  16 source=(${url}/${pkgname}-${_pkgver}.tar.gz)
  17 sha256sums=('6792a6a992050762edcca28ff3318cdb7de37dccf7bc30db59fcd7017eed13c5')
  18 b2sums=('325dc756fc6c6244e336cd6faeed2ab37817bdab8c0684586c44d551074fd2ec84bfcd3f4d5897db3196e783653a042699e5b9a8a3351d653992bb256956b652')
  19
  20 build() {
  21   cd ${pkgname}-${_pkgver}
  22   ./configure --prefix=/usr
  23   make V=1
  24 }
  25
  26 package() {
  27   cd ${pkgname}-${_pkgver}
  28   make DESTDIR="${pkgdir}" install
  29
  30   rm "${pkgdir}"/usr/share/man/man3/history.3 # conflicts with readline
  31   install -Dm 644 "${pkgdir}"/usr/share/man/man3/editline.3 "${pkgdir}"/usr/share/man/man3/el.3
  32
  33   install -Dm 644 ChangeLog -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  35 }
  36
  37 # vim: ts=2 sw=2 et: