glibmm/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgbase=glibmm
   6 pkgname=(glibmm glibmm-docs)
   7 pkgver=2.66.4
   8 pkgrel=1
   9 pkgdesc="C++ bindings for GLib"
  10 url="https://www.gtkmm.org/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(glib2 libsigc++)
  14 makedepends=(git meson mm-common perl-xml-parser clang)
  15 checkdepends=(glib-networking)
  16 options=(!emptydirs debug)
  17 _commit=646ca2c15dd03f804b92e3d547f22aa999a21677  # tags/2.66.4^0
  18 source=("git+https://gitlab.gnome.org/GNOME/glibmm.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd glibmm
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd glibmm
  28 }
  29
  30 build() {
  31   arch-meson glibmm build -D maintainer-mode=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package_glibmm() {
  40   depends+=(libsigc-2.0.so)
  41   provides=(libglibmm-2.4.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44
  45   # Split -docs
  46   mkdir -p docs/usr/share
  47   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  48 }
  49
  50 package_glibmm-docs() {
  51   pkgdesc+=" (documentation)"
  52   depends=()
  53   options=(!strip)
  54
  55   mv -t "$pkgdir" docs/*
  56 }