gparted/trunk/PKGBUILD

   1 # Maintainer: Giovanni Scafora <giovanni@archlinux.org>
   2 # Contributor: Andrew Simmons <andrew.simmons@gmail.com>
   3 # Contributor: György Balló <ballogy@freestart.hu>
   4
   5 pkgname=gparted
   6 pkgver=1.4.0
   7 pkgrel=1
   8 pkgdesc='A Partition Magic clone, frontend to GNU Parted'
   9 arch=('x86_64')
  10 url='https://gparted.org/'
  11 license=('GPL')
  12 depends=('parted' 'gtkmm3')
  13 makedepends=('intltool' 'itstool' 'pkg-config' 'yelp-tools' 'polkit')
  14 optdepends=('dosfstools: for FAT16 and FAT32 partitions'
  15             'jfsutils: for jfs partitions'
  16             'f2fs-tools: for Flash-Friendly File System'
  17             'btrfs-progs: for btrfs partitions'
  18             'exfatprogs: for exFAT partitions'
  19             'ntfs-3g: for ntfs partitions'
  20             'reiserfsprogs: for reiser partitions'
  21             'udftools: for UDF file system support'
  22             'xfsprogs: for xfs partitions'
  23             'nilfs-utils: for nilfs2 support'
  24             'polkit: to run gparted from application menu'
  25             'gpart: for recovering corrupt partition tables'
  26             'mtools: utilities to access MS-DOS disks'
  27             'xorg-xhost: authorization from wayland')
  28 validpgpkeys=('BB09FFB87563FA2E1A22146817A6D3FF338C9570') # "Curtis Gedak <gedakc@gmail.com>"
  29 source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz"{,.sig})
  30 sha256sums=('e5293a792e53fdbeba29c4a834113cd9603d0d639330da931a468bf3687887be'
  31             'SKIP')
  32
  33 build() {
  34   cd "${srcdir}/${pkgname}-${pkgver}"
  35
  36   ./configure --prefix=/usr \
  37       --sbindir=/usr/bin \
  38       --libexecdir=/usr/lib/gparted \
  39       --enable-online-resize \
  40       --enable-libparted-dmraid \
  41       --enable-xhost-root
  42   make
  43 }
  44
  45 package() {
  46   cd "${srcdir}/${pkgname}-${pkgver}"
  47
  48   make DESTDIR="${pkgdir}" install
  49
  50   # Install policy file
  51   install -D -m0644 org.gnome.gparted.policy \
  52       "${pkgdir}"/usr/share/polkit-1/actions/org.gnome.gparted.policy
  53 }