lzo/trunk/PKGBUILD

   1 # Contributor: Low Kian Seong <fastmail_low@speedymail.org>
   2 # Maintainer: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=lzo
   5 pkgver=2.10
   6 pkgrel=3
   7 pkgdesc="Portable lossless data compression library"
   8 arch=('x86_64')
   9 url="https://www.oberhumer.com/opensource/lzo"
  10 license=('GPL')
  11 depends=('glibc')
  12 source=(https://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
  13 sha1sums=('4924676a9bae5db58ef129dc1cebce3baa3c4b5d')
  14
  15 build() {
  16   cd lzo-${pkgver}
  17   ./configure --prefix=/usr --enable-shared
  18   make
  19
  20   # build minilzo
  21   gcc $CPPFLAGS $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
  22   gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
  23 }
  24
  25 check() {
  26   cd lzo-${pkgver}
  27   make test # Larger test
  28   make check
  29 }
  30
  31 package() {
  32   cd lzo-${pkgver}
  33   make DESTDIR="${pkgdir}" install
  34
  35   # install minilzo
  36   install -m 755 libminilzo.so.0 "${pkgdir}"/usr/lib
  37   install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
  38   cd "${pkgdir}"/usr/lib
  39   ln -s libminilzo.so.0 libminilzo.so
  40 }