portaudio/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Eric Belanger <eric@archlinux.org>
   4 # Contributor: Darwin Bautista <djclue917@gmail.com>
   5 # Contributor: Bob Finch <w9ya@qrparci.net>
   6
   7 pkgname=portaudio
   8 pkgver=19.7.0
   9 pkgrel=1
  10 epoch=1
  11 pkgdesc='A free, cross-platform, open source, audio I/O library.'
  12 arch=('x86_64')
  13 url="https://github.com/portaudio/portaudio/"
  14 license=('MIT')
  15 depends=('gcc-libs' 'glibc')
  16 makedepends=('alsa-lib' 'jack')
  17 provides=('libportaudio.so' 'libportaudiocpp.so')
  18 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz")
  19 sha512sums=('7e347a174109b661a685bcd617cc8fe00929c6fbf28f142fd7709a8ddbb9b5ed6e805be6647a44b4b9441b79e3474561de6f8e351b4ffc024952ed3e0e27ac1c')
  20 b2sums=('db16882e97e60ab47b37c6d8851aa29e16e321531f3890f70390d89364aee2c1a9b42be09e7534f38d1c9ca48dd466b512874731049e42759a674571d6054220')
  21
  22 prepare() {
  23   cd "${pkgname}-${pkgver}"
  24   (
  25     cd bindings/cpp
  26     autoreconf -fiv
  27   )
  28   autoreconf -fiv
  29 }
  30
  31 build() {
  32   cd "${pkgname}-${pkgver}"
  33   ./configure --prefix=/usr \
  34               --enable-cxx
  35   # build breaks with multiple jobs when building C++ bindings:
  36   # https://github.com/PortAudio/portaudio/issues/540
  37   make -j1
  38 }
  39
  40 package() {
  41   depends+=('libasound.so' 'libjack.so')
  42   cd "${pkgname}-${pkgver}"
  43   make DESTDIR="${pkgdir}" install
  44   install -vDm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  45   install -vDm 644 README.* -t "${pkgdir}/usr/share/doc/${pkgname}"
  46 }