e2fsprogs/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: judd <jvinet@zeroflux.org>
   3
   4 pkgname=e2fsprogs
   5 pkgver=1.46.4
   6 pkgrel=1
   7 pkgdesc="Ext2/3/4 filesystem utilities"
   8 arch=('x86_64')
   9 license=('GPL' 'LGPL' 'MIT')
  10 url="http://e2fsprogs.sourceforge.net"
  11 depends=('sh' 'util-linux-libs')
  12 makedepends=('systemd' 'util-linux')
  13 provides=('libcom_err.so'
  14           'libe2p.so'
  15           'libext2fs.so'
  16           'libss.so')
  17 backup=('etc/mke2fs.conf')
  18 options=('staticlibs')
  19 validpgpkeys=('3AB057B7E78D945C8C5591FBD36F769BC11804F0') # Theodore Ts'o <tytso@mit.edu>
  20 source=("https://www.kernel.org/pub/linux/kernel/people/tytso/${pkgname}/v${pkgver}/${pkgname}-${pkgver}.tar."{xz,sign}
  21         'MIT-LICENSE')
  22 sha256sums=('b11042533c1b1dcf17512f0da48e05b0c573dada1dd8b762864d10f4dc399713'
  23             'SKIP'
  24             'cc45386c1d71f438ad648fd7971e49e3074ad9dbacf9dd3a5b4cb61fd294ecbb')
  25
  26
  27 prepare() {
  28   cd "${srcdir}/${pkgname}-${pkgver}"
  29
  30   # Remove unnecessary init.d directory
  31   sed -i '/init\.d/s|^|#|' misc/Makefile.in
  32 }
  33
  34 build() {
  35   cd "${srcdir}/${pkgname}-${pkgver}"
  36
  37   ./configure \
  38       --prefix=/usr \
  39       --with-root-prefix="" \
  40       --libdir=/usr/lib \
  41       --sbindir=/usr/bin \
  42       --enable-elf-shlibs \
  43       --disable-fsck \
  44       --disable-uuidd \
  45       --disable-libuuid \
  46       --disable-libblkid
  47
  48   make
  49
  50   # regenerate locale files
  51   find po/ -name '*.gmo' -delete
  52   make -C po update-gmo
  53 }
  54
  55 package() {
  56   unset MAKEFLAGS
  57
  58   cd "${srcdir}/${pkgname}-${pkgver}"
  59   make DESTDIR="${pkgdir}" install install-libs
  60
  61   sed -i -e 's/^AWK=.*/AWK=awk/' "${pkgdir}/usr/bin/compile_et"
  62
  63   # remove references to build directory
  64   sed -i -e 's#^SS_DIR=.*#SS_DIR="/usr/share/ss"#' "${pkgdir}/usr/bin/mk_cmds"
  65   sed -i -e 's#^ET_DIR=.*#ET_DIR="/usr/share/et"#' "${pkgdir}/usr/bin/compile_et"
  66
  67   # remove static libraries with a shared counterpart
  68   rm "${pkgdir}"/usr/lib/lib{com_err,e2p,ext2fs,ss}.a
  69
  70   # install MIT license
  71   install -Dm644 "${srcdir}/MIT-LICENSE" \
  72     "${pkgdir}/usr/share/licenses/${pkgname}/MIT-LICENSE"
  73 }