libwnck3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=libwnck3
   5 pkgver=40.0
   6 pkgrel=1
   7 pkgdesc="Library to manage X windows and workspaces (via pagers, tasklists, etc.)"
   8 url="https://gitlab.gnome.org/GNOME/libwnck"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gtk3 startup-notification libxres)
  12 makedepends=(gobject-introspection gtk-doc git meson)
  13 _commit=d161ed31914711b97a1c6ebef0558d80ce51113b  # tags/40.0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/libwnck.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18     cd libwnck
  19     git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23     cd libwnck
  24 }
  25
  26 build() {
  27     arch-meson libwnck build -D gtk_doc=true
  28     meson compile -C build
  29 }
  30
  31 check() {
  32     meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36     meson install -C build --destdir "$pkgdir"
  37 }
  38
  39 # vim:set sw=4 et: