kactivitymanagerd/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=kactivitymanagerd
   5 pkgver=5.25.5
   6 pkgrel=1
   7 pkgdesc='System service to manage user activities and track the usage patterns'
   8 arch=(x86_64)
   9 url='https://kde.org/plasma-desktop/'
  10 license=(LGPL)
  11 depends=(kio)
  12 makedepends=(extra-cmake-modules boost)
  13 groups=(plasma)
  14 source=(https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz{,.sig})
  15 sha256sums=('96bc418188d561d1cc338970112d1c13be51405336b323b22ec21a1231a45443'
  16             'SKIP')
  17 validpgpkeys=('E0A3EB202F8E57528E13E72FD7574483BB57B18D'  # Jonathan Esk-Riddell <jr@jriddell.org>
  18               '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
  19               'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
  20               '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>
  21 options=(debug)
  22
  23 build() {
  24   cmake -B build -S $pkgname-$pkgver \
  25     -DCMAKE_INSTALL_LIBEXECDIR=lib \
  26     -DBUILD_TESTING=OFF
  27   cmake --build build
  28 }
  29
  30 package() {
  31   DESTDIR="$pkgdir" cmake --install build
  32 }