mono/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Giancarlo Razzolinit <grazzolini@gmail.com>
   3 # Contributor: Daniel Isenmann <daniel@archlinux.org>
   4 # Contributor: Brice Carpentier <brice@dlfp.org>
   5
   6 pkgname=mono
   7 _gitcommit=ed0788bf61f08a1f0424de4be6f6af1949519e10
   8 pkgver=6.12.0.177
   9 pkgrel=1
  10 pkgdesc='Free implementation of the .NET platform including runtime and compiler'
  11 url='https://www.mono-project.com/'
  12 arch=('x86_64')
  13 license=('GPL' 'LGPL2.1' 'MPL')
  14 depends=('zlib' 'libgdiplus>=4.2' 'sh' 'python' 'ca-certificates')
  15 makedepends=('cmake' 'git')
  16 provides=('monodoc')
  17 conflicts=('monodoc')
  18 install=mono.install
  19 source=(${pkgname}::"git+https://github.com/mono/mono#commit=${_gitcommit}"
  20         git+https://github.com/mono/aspnetwebstack
  21         git+https://github.com/mono/Newtonsoft.Json
  22         git+https://github.com/mono/cecil
  23         git+https://github.com/mono/rx
  24         git+https://github.com/mono/ikvm-fork
  25         git+https://github.com/mono/ikdasm
  26         git+https://github.com/mono/reference-assemblies
  27         git+https://github.com/mono/NUnitLite
  28         git+https://github.com/mono/NuGet.BuildTasks
  29         git+https://github.com/mono/boringssl
  30         git+https://github.com/mono/corefx
  31         git+https://github.com/mono/bockbuild
  32         git+https://github.com/mono/linker
  33         git+https://github.com/mono/roslyn-binaries
  34         git+https://github.com/mono/corert
  35         git+https://github.com/mono/xunit-binaries
  36         git+https://github.com/mono/api-doc-tools
  37         git+https://github.com/mono/api-snapshot
  38         mono.binfmt.d)
  39 sha256sums=('SKIP'
  40             'SKIP'
  41             'SKIP'
  42             'SKIP'
  43             'SKIP'
  44             'SKIP'
  45             'SKIP'
  46             'SKIP'
  47             'SKIP'
  48             'SKIP'
  49             'SKIP'
  50             'SKIP'
  51             'SKIP'
  52             'SKIP'
  53             'SKIP'
  54             'SKIP'
  55             'SKIP'
  56             'SKIP'
  57             'SKIP'
  58             '9a657fc153ef4ce23bf5fc369a26bf4a124e9304bde3744d04c583c54ca47425')
  59
  60 pkgver() {
  61   cd ${pkgname}
  62   git describe --tags | sed 's/^v//;s/^mono-//;s/\([^-]*-g\)/r\1/;s/-/./g'
  63 }
  64
  65 prepare() {
  66   cd ${pkgname}
  67   git submodule init
  68   git config submodule."external/aspnetwebstack".url "${srcdir}/aspnetwebstack"
  69   git config submodule."external/Newtonsoft.Json".url "${srcdir}/Newtonsoft.Json"
  70   git config submodule."external/cecil".url "${srcdir}/cecil"
  71   git config submodule."external/rx".url "${srcdir}/rx"
  72   git config submodule."external/ikvm".url "${srcdir}/ikvm-fork"
  73   git config submodule."external/ikdasm".url "${srcdir}/ikdasm"
  74   git config submodule."external/reference-assemblies".url "${srcdir}/reference-assemblies"
  75   git config submodule."external/nunit-lite".url "${srcdir}/NUnitLite"
  76   git config submodule."external/nuget-buildtasks".url "${srcdir}/NuGet.BuildTasks"
  77   git config submodule."external/cecil-legacy".url "${srcdir}/cecil"
  78   git config submodule."external/boringssl".url "${srcdir}/boringssl"
  79   git config submodule."external/corefx".url "${srcdir}/corefx"
  80   git config submodule."external/bockbuild".url "${srcdir}/bockbuild"
  81   git config submodule."external/linker".url "${srcdir}/linker"
  82   git config submodule."external/roslyn-binaries".url "${srcdir}/roslyn-binaries"
  83   git config submodule."external/corert".url "${srcdir}/corert"
  84   git config submodule."external/xunit-binaries".url "${srcdir}/xunit-binaries"
  85   git config submodule."external/api-doc-tools".url "${srcdir}/api-doc-tools"
  86   git config submodule."external/api-snapshot".url "${srcdir}/api-snapshot"
  87   git submodule update --recursive
  88 }
  89
  90 build() {
  91   cd ${pkgname}
  92   CFLAGS+=" -ffat-lto-objects" \
  93   ./autogen.sh \
  94     --prefix=/usr \
  95     --sysconfdir=/etc \
  96     --bindir=/usr/bin \
  97     --sbindir=/usr/bin \
  98     --with-mcs-docs=no
  99   make
 100   make -C mcs/jay
 101 }
 102
 103 package() {
 104   cd ${pkgname}
 105   make DESTDIR="${pkgdir}" install
 106   make -C mcs/jay DESTDIR="${pkgdir}" prefix=/usr INSTALL=../../install-sh install
 107   install -Dm 644 "${srcdir}/mono.binfmt.d" "${pkgdir}/usr/lib/binfmt.d/mono.conf"
 108 }
 109
 110 # vim: ts=2 sw=2 et: