pavucontrol/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   3 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   4 # Contributor: William Rea <sillywilly@gmail.com>
   5
   6 pkgname=pavucontrol
   7 pkgver=5.0+r35+g964f298
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc="PulseAudio Volume Control"
  11 url="https://freedesktop.org/software/pulseaudio/pavucontrol/"
  12 arch=(x86_64)
  13 license=(GPL)
  14 depends=(gtkmm3 libsigc++ libcanberra json-glib)
  15 makedepends=(meson lynx git)
  16 checkdepends=(tidy)
  17 optdepends=("pulseaudio: Audio backend")
  18 options=(debug)
  19 _commit=964f2987a46aa984d9ba83369b1f27c0bb28e9af  # master
  20 source=("git+https://gitlab.freedesktop.org/pulseaudio/pavucontrol.git#commit=$_commit"
  21         0001-meson-Define-HAVE_PULSE_MESSAGING_API-when-available.patch
  22         0002-fix-focus-trap-in-output-selection-widget.patch)
  23 sha256sums=('SKIP'
  24             '915c73ebd14b9ce53600a4c636c23a0d2a329f887360512eacc2f6d621394ae9'
  25             'd9ab38eea6838a95e6d337c07292cc74de1f7c875f65f967f5f89a141021fc15')
  26
  27 pkgver() {
  28   cd pavucontrol
  29   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  30 }
  31
  32 prepare() {
  33   cd pavucontrol
  34
  35   # Fix meson build
  36   git apply -3 ../0001-meson-Define-HAVE_PULSE_MESSAGING_API-when-available.patch
  37
  38   # https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/issues/124
  39   # https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/merge_requests/73
  40   git apply -3 ../0002-fix-focus-trap-in-output-selection-widget.patch
  41 }
  42
  43 build() {
  44   arch-meson pavucontrol build
  45   meson compile -C build
  46 }
  47
  48 check() {
  49   meson test -C build --print-errorlogs
  50 }
  51
  52 package() {
  53   meson install -C build --destdir "$pkgdir"
  54 }