gjs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=gjs
   5 pkgver=1.72.2
   6 pkgrel=1
   7 epoch=2
   8 pkgdesc="Javascript Bindings for GNOME"
   9 url="https://wiki.gnome.org/Projects/Gjs"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(cairo gobject-introspection-runtime js91 dconf readline
  13          libsysprof-capture)
  14 makedepends=(gobject-introspection git meson dbus)
  15 checkdepends=(xorg-server-xvfb gtk3 gtk4)
  16 provides=(libgjs.so)
  17 options=(debug)
  18 _commit=56d74f6fd6398d933696eaf96c1f3a3f2a52cbf9  # tags/1.72.2^0
  19 source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd gjs
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd gjs
  29
  30   # Work around https://github.com/mesonbuild/meson/issues/10577
  31   sed -e "/protocol/s/'tap'/'exitcode'/" \
  32       -i {test,installed-tests{,/js}}/meson.build
  33 }
  34
  35 build() {
  36   CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
  37   CXXFLAGS="${CXXFLAGS/-O2/-O3} -fno-semantic-interposition"
  38   LDFLAGS+=" -Wl,-Bsymbolic-functions"
  39
  40   arch-meson gjs build -D installed_tests=false
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   xvfb-run -s '-nolisten local' \
  46     meson test -C build --print-errorlogs
  47 }
  48
  49 package() {
  50   depends+=(libreadline.so)
  51   meson install -C build --destdir "$pkgdir"
  52 }
  53
  54 # vim:set sw=2 et: