qt5-networkauth/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt5-networkauth
   5 _qtver=5.15.2
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Network authentication module'
  12 depends=(qt5-base)
  13 groups=(qt qt5)
  14 _pkgfqn="${pkgname/5-/}-everywhere-src-${_qtver}"
  15 source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
  16 sha256sums=('fcc2ec42faa68561efa8f00cd72e662fbc06563ebc6de1dc42d96bb2997acd85')
  17
  18 prepare() {
  19   mkdir -p build
  20 }
  21
  22 build() {
  23   cd build
  24
  25   qmake ../${_pkgfqn}
  26   make
  27 }
  28
  29 package() {
  30   cd build
  31   make INSTALL_ROOT="$pkgdir" install
  32
  33   # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  34   find "$pkgdir/usr/lib" -type f -name '*.prl' \
  35     -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
  36
  37   install -d "$pkgdir"/usr/share/licenses
  38   ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
  39 }