arch-rebuild-order/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   2
   3 pkgname=arch-rebuild-order
   4 pkgver=0.3.1
   5 pkgrel=1
   6 pkgdesc='CLI tool to determine the rebuild order of provided package(s)'
   7 url='https://gitlab.archlinux.org/archlinux/arch-rebuild-order'
   8 arch=('x86_64')
   9 license=('MIT')
  10 depends=('glibc' 'libalpm.so')
  11 makedepends=('cargo' 'mandown' 'git')
  12 groups=('archlinux-tools')
  13 options=('debug')
  14 source=(git+https://gitlab.archlinux.org/archlinux/arch-rebuild-order.git#tag=v$pkgver?signed)
  15 sha512sums=('SKIP')
  16 validpgpkeys=("E499C79F53C96A54E572FEE1C06086337C50773E")
  17
  18 prepare() {
  19   cd ${pkgname}
  20   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21 }
  22
  23 build() {
  24   cd ${pkgname}
  25   cargo build --frozen --release --all-features
  26 }
  27
  28 check() {
  29   cd ${pkgname}
  30   cargo test --frozen --all-features
  31 }
  32
  33 package() {
  34   cd ${pkgname}
  35   make install DESTDIR="$pkgdir" PREFIX=/usr
  36
  37   install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  38 }