gegl/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Daniel Isenmann <daniel@archlinux.org>
   2
   3 pkgname=gegl
   4 _tag='e10b8c9114614dc724390a7e737eafd97f47430f'
   5 pkgver=0.4.44
   6 pkgrel=1
   7 pkgdesc='Graph based image processing framework'
   8 arch=('x86_64')
   9 url='https://www.gegl.org/'
  10 license=('GPL3' 'LGPL3')
  11 depends=('babl' 'jasper' 'json-glib' 'lensfun' 'libgexiv2' 'libraw' 'librsvg' 'libspiro'
  12          'libtiff' 'luajit' 'openexr' 'poppler-glib' 'suitesparse')
  13 makedepends=('exiv2' 'ffmpeg' 'git' 'glu' 'gobject-introspection' 'intltool' 'mesa'
  14              'meson' 'python-gobject' 'ruby' 'vala')
  15 optdepends=('ffmpeg: ffmpeg plugin'
  16             'graphviz: for gegl-introspect')
  17 source=("git+https://gitlab.gnome.org/GNOME/gegl.git#tag=$_tag")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd "${pkgname}"
  22   git describe --tags | sed 's/^GEGL_//;s/_$//;s/_/./g;s/-/+/g'
  23 }
  24
  25 build() {
  26   mkdir -p build
  27   cd build
  28   arch-meson ../"${pkgname}" \
  29     -Dworkshop=true \
  30     -Dmrg=disabled \
  31     -Dmaxflow=disabled
  32   ninja
  33 }
  34
  35 check() {
  36   cd build
  37   ninja test || :
  38 }
  39
  40 package() {
  41   cd build
  42   DESTDIR="${pkgdir}" ninja install
  43 }