gnome-getting-started-docs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-getting-started-docs
   5 pkgver=3.38.1
   6 pkgrel=1
   7 pkgdesc="Help a new user get started in GNOME"
   8 url="https://gitlab.gnome.org/GNOME/gnome-getting-started-docs"
   9 license=(CCPL:by-sa)
  10 arch=(any)
  11 # gst plugins required to decode help videos
  12 depends=(yelp gst-plugins-base gst-plugins-good)
  13 makedepends=(yelp-tools git)
  14 groups=(gnome)
  15 _commit=b13e80f4abcf2addf48b8c426be3ed7b8e06fb85  # master
  16 source=("git+https://gitlab.gnome.org/GNOME/gnome-getting-started-docs.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   git tag -f 3.38.1 b13e80f4abcf2addf48b8c426be3ed7b8e06fb85 # Fixup missing tag
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  33   make
  34 }
  35
  36 package() {
  37   cd $pkgname
  38   make DESTDIR="$pkgdir" install
  39 }