gv/repos/extra-x86_64/PKGBUILD

   1 # Contributor: Eric Bélanger <eric@archlinux.org>
   2
   3 pkgname=gv
   4 pkgver=3.7.4
   5 pkgrel=5
   6 pkgdesc="A program to view PostScript and PDF documents"
   7 arch=('x86_64')
   8 url="https://www.gnu.org/software/gv/"
   9 license=('GPL3')
  10 depends=('xaw3d' 'ghostscript')
  11 optdepends=('perl: gv-update-userconfig')
  12 options=('emptydirs')
  13 source=(https://ftp.gnu.org/gnu/gv/${pkgname}-${pkgver}.tar.gz{,.sig} gv.desktop)
  14 sha256sums=('2162b3b3a95481d3855b3c4e28f974617eef67824523e56e20b56f12fe201a61'
  15             'SKIP'
  16             '9b272fe86a7bdfbb170dfd850ae18204ef1ed0982bd88a8b2b3db7a7f5e87eb7')
  17 validpgpkeys=('5A15E3DBE8D7DE6F2AC69EB5B1AF90204976D4CD')
  18
  19 prepare() {
  20   cd ${pkgname}-${pkgver}
  21   sed -i -e "s:-dGraphicsAlphaBits=2:\0 -dAlignToPixels=0:" src/Makefile.{am,in}
  22 }
  23
  24 build() {
  25   cd ${pkgname}-${pkgver}
  26   ./configure --prefix=/usr
  27   make
  28 }
  29
  30 package() {
  31   cd ${pkgname}-${pkgver}
  32   make DESTDIR="${pkgdir}" install
  33   install -D -m644 ../gv.desktop "${pkgdir}/usr/share/applications/gv.desktop"
  34   install -D -m644 src/gv_icon.xbm "${pkgdir}/usr/share/pixmaps/gv.xbm"
  35 }