liblc3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
   3 # Contributor: Florian Hülsmann <fh@cbix.de>
   4
   5 pkgname=liblc3
   6 pkgver=1.0.3
   7 pkgrel=1
   8 pkgdesc="Low Complexity Communication Codec library and tools"
   9 url="https://github.com/google/liblc3"
  10 arch=(x86_64)
  11 license=(Apache)
  12 depends=(glibc)
  13 makedepends=(meson git)
  14 provides=(liblc3.so)
  15 _commit=3d769309ffacb3c18b4a0bdd6b46544eb26bbfb2  # tags/v1.0.3
  16 source=("git+$url#commit=$_commit")
  17 b2sums=('SKIP')
  18
  19 pkgver() {
  20   cd liblc3
  21   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd liblc3
  26 }
  27
  28 build() {
  29   arch-meson liblc3 build -D tools=true
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   meson install -C build --destdir "$pkgdir"
  39   install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 liblc3/README.md
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: