libplist/trunk/PKGBUILD

   1 # Maintainer:
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: Gabriel Martinez < reitaka at gmail dot com >
   5
   6 pkgname=libplist
   7 pkgver=2.3.0
   8 pkgrel=1
   9 pkgdesc="A library to handle Apple Property List format whereas it's binary or XML"
  10 url="https://libimobiledevice.org/"
  11 arch=('x86_64')
  12 license=('GPL2' 'LGPL2.1')
  13 depends=('gcc-libs')
  14 makedepends=('python' 'cython' 'autoconf-archive' 'python-setuptools')
  15 optdepends=('python: for the Python bindings')
  16 source=(https://github.com/libimobiledevice/libplist/releases/download/$pkgver/$pkgname-$pkgver.tar.bz2)
  17 sha256sums=('4e8580d3f39d3dfa13cefab1a13f39ea85c4b0202e9305c5c8f63818182cac61')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21   ./configure --prefix=/usr
  22   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  23   make
  24 }
  25
  26 check() {
  27   cd $pkgname-$pkgver
  28   make check
  29 }
  30
  31 package() {
  32   cd $pkgname-$pkgver
  33   make DESTDIR="$pkgdir" install
  34   install -D -m644 cython/plist.pxd "${pkgdir}"/usr/include/plist/cython/plist.pxd
  35 }