lightdm/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Morfeo <morfeo89@hotmail.it>
   3
   4 pkgbase=lightdm
   5 pkgname=(
   6   lightdm
   7   liblightdm-qt5
   8 )
   9 pkgver=1.32.0
  10 pkgrel=4
  11 epoch=1
  12 pkgdesc='A lightweight display manager'
  13 arch=(x86_64)
  14 url=https://github.com/canonical/lightdm
  15 license=(
  16   GPL3
  17   LGPL3
  18 )
  19 makedepends=(
  20   glib2
  21   git
  22   gobject-introspection
  23   gtk-doc
  24   intltool
  25   itstool
  26   libgcrypt
  27   libx11
  28   libxcb
  29   libxdmcp
  30   libxklavier
  31   pam
  32   polkit
  33   qt5-base
  34   vala
  35   xorg-server
  36   xorg-xmodmap
  37   xorg-xrdb
  38   yelp-tools
  39 )
  40 _tag=9e72b5b3072ff9990211f35aa2a48e971ff710c7
  41 source=(
  42   git+https://github.com/CanonicalLtd/lightdm.git?signed#tag=${_tag}
  43   lightdm.service
  44   lightdm.sysusers
  45   lightdm.tmpfiles
  46   lightdm.pam
  47   lightdm-autologin.pam
  48   lightdm.rules
  49   lightdm-default-config.patch
  50   Xsession
  51 )
  52 validpgpkeys=(497851B5D455C606543F2B9318EAA1890F7C882E) # Robert Ancell <robert.ancell@gmail.com>
  53 b2sums=('SKIP'
  54         'edf722759d922428f5aba6793923e3b1846ddcfab67fe3e2bac109edf16219e037242aa5536fbab346e04295069b4fc0fa98062e3006088ec9780c58e503463a'
  55         '901702d0bc471de1f8f796576f4d3b451daf632dd703fecc3be7228f9b8deb911d834cd53e8fd5ee24227f46be6a4789b1983a96ec7c32d170d7427ef00c5293'
  56         '8d04b2f9b861a65707bc1965a80f64d4e03cfe09c84addda27e8dca74b40f4fe85c43773e41dcb972772df7684d4bfc2aacd32c9bc1ac9fa1c2a8d6c27cd02b2'
  57         '11f4c568c6b766d3baf65ea91be2ec0641381a6c195ef460a9a0e282591c1211603d0a3db630e901079fba28819a4efab45bb8b722947dfac37659daafe14aaf'
  58         '3349ad387eb3c928e3314f557800f88abb58eb2d5f2e4ccb882c4469f7ed26f940cd70a89ad33484eb3f14246ea7c7402a24396aeeea7046c002bedace631c26'
  59         '9e7b4f2adacfa18e9c029f93b922da45e3326266495a1919465f299fa630d769eaaa2101d76966cea496f66c4bd8469c73ef55acde5cd19fa559921c192acd04'
  60         'd404466a551a42ac486564c5016baaae2276ec4126ae237538836e27e58b645dccf3ad3197c5c89d637d9bb678c3d7c0568a114d22fea2abec2d5e4eb0fb2721'
  61         '7785c19bb2343732d75dd2abd744148ae8baa6d8ad2b295a8e28d5eb78d7bd525e17784ae8a75784ab4cdb3fde73c66789b1bc033c53dafe13f8d19988e5ba18')
  62
  63 prepare() {
  64   cd lightdm
  65   patch -Np1 -i ../lightdm-default-config.patch
  66   NOCONFIGURE=1 ./autogen.sh
  67 }
  68
  69 pkgver() {
  70   cd lightdm
  71   git describe --tags
  72 }
  73
  74 build() {
  75   cd lightdm
  76   export MOC5=moc-qt5
  77   ./configure \
  78     --prefix=/usr \
  79     --libexecdir=/usr/lib/lightdm \
  80     --localstatedir=/var \
  81     --sbindir=/usr/bin \
  82     --sysconfdir=/etc \
  83     --disable-static \
  84     --disable-tests \
  85     --enable-gtk-doc \
  86     --with-greeter-user=lightdm \
  87     --with-greeter-session=lightdm-gtk-greeter
  88   make
  89 }
  90
  91 package_lightdm() {
  92   depends=(
  93     glib2
  94     libgcrypt
  95     libx11
  96     libxcb
  97     libxdmcp
  98     libxklavier
  99     pam
 100     polkit
 101     xorg-server
 102     xorg-xmodmap
 103     xorg-xrdb
 104   )
 105   optdepends=(
 106     'accountsservice: Enhanced user accounts handling'
 107     'lightdm-gtk-greeter: GTK greeter'
 108     'xorg-server-xephyr: LightDM test mode'
 109   )
 110   backup=(
 111     etc/apparmor.d/lightdm-guest-session
 112     etc/lightdm/keys.conf
 113     etc/lightdm/lightdm.conf
 114     etc/lightdm/users.conf
 115     etc/lightdm/Xsession
 116     etc/pam.d/lightdm
 117     etc/pam.d/lightdm-autologin
 118     etc/pam.d/lightdm-greeter
 119   )
 120
 121   cd lightdm
 122
 123   make DESTDIR="${pkgdir}" install
 124   make DESTDIR="${pkgdir}" -C liblightdm-qt uninstall
 125   install -m 755 ../Xsession "${pkgdir}"/etc/lightdm/Xsession
 126   rm -rf "${pkgdir}"/etc/init
 127   rm -rf "${pkgdir}"/usr/include/lightdm-qt{,5}-*
 128
 129   # PAM
 130   install -m 644 ../lightdm.pam "${pkgdir}"/etc/pam.d/lightdm
 131   install -m 644 ../lightdm-autologin.pam "${pkgdir}"/etc/pam.d/lightdm-autologin
 132
 133   # PolicyKit
 134   install -dm 750 -g 102 "${pkgdir}"/usr/share/polkit-1/rules.d
 135   install -m 644 ../lightdm.rules "${pkgdir}"/usr/share/polkit-1/rules.d/lightdm.rules
 136
 137   # Systemd
 138   install -dm 755 "${pkgdir}"/usr/lib/{systemd/system,sysusers.d,tmpfiles.d}
 139   install -m 644 ../lightdm.service "${pkgdir}"/usr/lib/systemd/system/lightdm.service
 140   install -m 644 ../lightdm.sysusers "${pkgdir}"/usr/lib/sysusers.d/lightdm.conf
 141   install -m 644 ../lightdm.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/lightdm.conf
 142 }
 143
 144 package_liblightdm-qt5() {
 145   pkgdesc='LightDM Qt client library'
 146   depends=(
 147     lightdm
 148     qt5-base
 149   )
 150   options=(!emptydirs)
 151
 152   cd lightdm
 153   make DESTDIR="${pkgdir}" -C liblightdm-gobject install
 154   make DESTDIR="${pkgdir}" -C liblightdm-qt install
 155   make DESTDIR="${pkgdir}" -C liblightdm-gobject uninstall
 156   find "${pkgdir}" -type d -name *qt[!5]* -exec rm -rf {} +
 157   find "${pkgdir}" -type f  -name *qt[!5]* -exec rm {} +
 158   find "${pkgdir}" -type l  -name *qt[!5]* -exec rm {} +
 159 }
 160
 161 # vim: ts=2 sw=2 et: