memcached/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Dan McGee <dan@archlinux.org>
   3 # Contributor: Michael Irwin <6d6469@gmail.com>
   4
   5 pkgname=memcached
   6 pkgver=1.6.19
   7 pkgrel=1
   8 pkgdesc='Distributed memory object caching system'
   9 url='https://memcached.org/'
  10 arch=('x86_64')
  11 license=('GPL')
  12 depends=('glibc' 'libevent' 'libseccomp' 'libseccomp.so')
  13 optdepends=('perl: for memcached-tool usage')
  14 source=(https://www.memcached.org/files/${pkgname}-${pkgver}.tar.gz
  15         memcached.service.patch
  16         memcached.tmpfiles
  17         memcached.sysusers
  18         0001-tests-enable-drop_privileges-by-default-for-better-s.patch
  19         0001-seccomp-extend-syscalls-tested-on-Linux-6.1-with-gli.patch)
  20 sha512sums=('60d93065e0ef2b17e9da5370a497a4fbfc64c0af70e14fdfdab60c0c94c0b19e30da31d615e19565474c278141a4cb401c65fd79bd70947dd96a9fee81824a74'
  21             'dd21f49062054c601469f9abc9ee39a0f06c604e8805e7bc9bf2cfa65429962f93e7ac67764257c578fc15b1e75394956f350162c99b084c76a6e14d9331f31f'
  22             '960705ff74d25afed477e0b2a5872a3a4fb49ed3105a351f0d0224abc947778f9dbda81e80be94ab636da4a8411a9dd56a8fd4513e5b86a3096a14fa67f1548b'
  23             'e6ddcab9a6fee024072b6363ef60aa176ed258369bf3a17d475f19b1f410ffd6195b9c5737dc5b1371e8974b44bdbdaa109927acaeb54fb40302a5d67d7c13a8'
  24             '5da2a4fb0cdaefe9527dec67e01d881161c49a1593f11ddccf28fb55cbc25fe841ea8eca8a50387e2fef5bc304f12a5c9af4909543eafc0f8865dea39f9e8355'
  25             '8d2518507cf843202dc90c10f6fce3c3fc9b41c7aaf10ff0b862c31d30bbbec7de92f9be0327ea3e58e77e29ae2a12b2f47370502bbddc04324f394cfdd7d4a8')
  26
  27 prepare() {
  28   cd ${pkgname}-${pkgver}
  29   patch -Np1 < ../0001-seccomp-extend-syscalls-tested-on-Linux-6.1-with-gli.patch
  30   patch -Np1 < ../0001-tests-enable-drop_privileges-by-default-for-better-s.patch
  31   patch -Np1 < ../memcached.service.patch
  32   sed -e 's/^##safer##//g' -i scripts/*.service
  33 }
  34
  35 build() {
  36   cd ${pkgname}-${pkgver}
  37   ./configure \
  38     --prefix=/usr \
  39     --enable-seccomp
  40   make
  41 }
  42
  43 check() {
  44   cd ${pkgname}-${pkgver}
  45   make test
  46 }
  47
  48 package() {
  49   cd ${pkgname}-${pkgver}
  50   make DESTDIR="${pkgdir}" install
  51
  52   install -Dm 755 scripts/memcached-tool -t "${pkgdir}/usr/bin"
  53   install -Dm 644 scripts/memcached-tool.1 -t "${pkgdir}/usr/share/man/man1"
  54
  55   install -Dm 644 scripts/*.service -t "${pkgdir}/usr/lib/systemd/system"
  56   install -Dm 644 ../memcached.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/memcached.conf"
  57   install -Dm 644 ../memcached.sysusers "${pkgdir}/usr/lib/sysusers.d/memcached.conf"
  58 }
  59
  60 # vim: ts=2 sw=2 et: