networkmanager-pptp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-pptp
   5 pkgver=1.2.12
   6 pkgrel=1
   7 pkgdesc="NetworkManager VPN plugin for PPTP"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 _pppver=2.4.9
  12 depends=(
  13   libnm
  14   libsecret
  15   "ppp=$_pppver"
  16   pptpclient
  17 )
  18 makedepends=(
  19   git
  20   intltool
  21   libnma
  22   libnma-gtk4
  23   python
  24 )
  25 optdepends=(
  26   'libnma-gtk4: GUI support (GTK 4)'
  27   'libnma: GUI support (GTK 3)'
  28 )
  29 _commit=ad5a2951d5f281eeea482404058ace8d15e23f30  # tags/1.2.12^0
  30 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-pptp.git#commit=$_commit")
  31 sha256sums=('SKIP')
  32
  33 pkgver() {
  34   cd NetworkManager-pptp
  35   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  36 }
  37
  38 prepare() {
  39   cd NetworkManager-pptp
  40   intltoolize --automake --copy
  41   autoreconf -fvi
  42 }
  43
  44 build() {
  45   cd NetworkManager-pptp
  46   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  47     --libexecdir=/usr/lib --disable-static --with-gtk4 \
  48     --with-pppd-plugin-dir=/usr/lib/pppd/$_pppver
  49   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  50   make
  51 }
  52
  53 package() {
  54   cd NetworkManager-pptp
  55   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  56 }
  57
  58 # vim:set sw=2 sts=-1 et: